[VB.NET] การคิดค่าบริการทั้งแบบ Service Charge และ None Service Charge ในรายการเดียว

thongkorn

โค้ด VB .NET (2010) กับการคิดค่าบริการ (Service Charge) และคำนวณหาภาษีทั้งแบบไม่คิดภาษี แบบรวมภาษี และแบบแยกภาษี ... อันนี้ไม่ใช่ดราม่านะครับ แต่เป็นการคิดคำนวณ Service Charge เพราะจริงๆแล้วตามโรงแรมต่างๆ หรือร้านอาหารใหญ่ๆ เขาไม่ได้คิดไปหมดทุกรายการ หลักๆก็จะเป็นค่าอาหาร ส่วนพวกห้องพัก หรือห้องคาราโอเกะพวกนี้จะไม่คิด ดังนั้นการคำนวณก็จะต้องแยกออกจากกัน เช่น ตัวอย่างรายการแรกคิด Service Charge เพียงค่าเดียว ก็จะเอาค่า 1,000 บาท (ไม่ใช่รวมหมด 3,000) มาหา 10% ของ Service Charge = 100 ก็จะได้ค่ารวม 1,100 บาท จากนั้นก็จะนำไปรวมกับค่าที่ไม่คิดอีก 2,000 ค่าที่ได้ทั้ง 2 มารวมกันเพื่อนำไปคำนวณหาภาษีอีกทีครับ ซึ่งปกติจะคิดแบบแยกภาษี (ภาระของผู้บริโภคนั่นเอง)

ในงานจริงเราจะต้องกำหนดสินค้า/บริการมาไว้ก่อนล่วงหน้าแล้ว ว่าอันไหนคิดหรือไม่คิด Service Charge สำหรับโค้ดชุดนี้ผมเลยนำเสนอวิธีการควบคุม #DataGridView ด้วยการเขียนโค้ดทั้งหมดล้วนๆ หรือที่เรียกกันว่า Run Time (สั่งรันถึงจะเห็นผลลัพธ์) ไว้ให้สำหรับชาว VB ได้ศึกษากัน

มาดูโค้ดกันเถอะ ...

1. Public Class frmServiceChargeVat
   
2. 
   
3.     ' / --------------------------------------------------------------------------------
   
4.     '/ Don't forget to set Form has KeyPreview = True
   
5.     Private Sub frmServiceChargeVat_KeyDown(ByVal sender As Object, ByVal e As System.Windows.Forms.KeyEventArgs) Handles Me.KeyDown
   
6.         '/ การกดฟังค์ชั่นคีย์
   
7.         Select Case e.KeyCode
   
8.             Case Keys.F7
   
9.                 '/ Add Row
   
10.                 Call btnAddRow_Click(sender, e)
    
11.             Case Keys.F8
    
12.                 '/ Remove Row
    
13.                 Call btnRemoveRow_Click(sender, e)
    
14.         End Select
    
15.     End Sub
    
16. 
    
17.     ' / --------------------------------------------------------------------------------
    
18.     Private Sub frmServiceChargeVat_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
    
19.         Me.KeyPreview = True  '/ สามารถกดปุ่มฟังค์ชั่นคีย์ลงในฟอร์มได้
    
20.         With cmbTax
    
21.             .Items.Add("None Vat")
    
22.             .Items.Add("Include Vat")
    
23.             .Items.Add("Exclude Vat")
    
24.         End With
    
25.         cmbTax.SelectedIndex = 2
    
26.         '//
    
27.         Call InitializeGrid()
    
28.         Call FillDataSample()   '/ ตัวอย่างสมมุติ
    
29.         Call CalSumTotal()  '/ รวมจำนวนเงิน
    
30.         '//
    
31.         Label7.Anchor = AnchorStyles.Bottom + AnchorStyles.Left
    
32.         cmbTax.Anchor = AnchorStyles.Bottom + AnchorStyles.Left
    
33.     End Sub
    
34. 
    
35.     ' / --------------------------------------------------------------------------------
    
36.     ' / การตั้งค่า DataGridView แบบ @Run Time หรือ Dynamically.
    
37.     Private Sub InitializeGrid()
    
38.         With dgvData
    
39.             .RowHeadersVisible = False
    
40.             .AllowUserToAddRows = False
    
41.             .AllowUserToDeleteRows = False
    
42.             .AllowUserToResizeRows = False
    
43.             .MultiSelect = False
    
44.             .ReadOnly = False
    
45.             .RowTemplate.MinimumHeight = 27
    
46.             .RowTemplate.Height = 27
    
47.             .Font = New Font("Tahoma", 10)
    
48.             '/ Columns Specified
    
49.             '/ Index = 0
    
50.             .Columns.Add("PK", "Primary Key")
    
51.             With .Columns("PK")
    
52.                 .ReadOnly = True
    
53.                 .DefaultCellStyle.BackColor = Color.LightGoldenrodYellow
    
54.                 .Visible = True 'False '/ ปกติหลัก Primary Key จะต้องถูกซ่อนไว้
    
55.             End With
    
56.             .Columns.Add("ProductID", "Product ID") '/ Index = 1
    
57.             .Columns.Add("ProductName", "Product Name") '/ Index = 2
    
58.             '/ Read Only
    
59.             .Columns(1).ReadOnly = True '/ รหัสสินค้า
    
60.             .Columns(2).ReadOnly = True '/ ชื่อสินค้า
    
61.             '/
    
62.             .Columns.Add("Quantity", "Quantity") '/ Index = 3
    
63.             .Columns("Quantity").ValueType = GetType(Integer)
    
64.             .Columns.Add("UnitPrice", "Unit Price") '/ Index = 4
    
65.             .Columns("UnitPrice").ValueType = GetType(Double)
    
66.             '/ Index = 5 (CheckBox) ... เลือกว่าคิด Service Charge หรือไม่
    
67.             Dim chkServiceCharge As New DataGridViewCheckBoxColumn
    
68.             .Columns.Add(chkServiceCharge)
    
69.             chkServiceCharge.HeaderText = "Service Charge"
    
70.             chkServiceCharge.Name = "chkServiceCharge"
    
71.             '/ Index = 6 ... Total = (จำนวน x ราคา)
    
72.             .Columns.Add("Total", "Total")
    
73.             .Columns("Total").ValueType = GetType(Double)
    
74.             '/ Total Column
    
75.             With .Columns("Total")
    
76.                 .ReadOnly = True
    
77.                 .DefaultCellStyle.BackColor = Color.LightGoldenrodYellow
    
78.                 .DefaultCellStyle.ForeColor = Color.Blue
    
79.                 .DefaultCellStyle.Font = New Font(dgvData.Font, FontStyle.Bold)
    
80.             End With
    
81.             '/ Alignment MiddleRight only columns 3, 4 and 6
    
82.             For i As Byte = 3 To 6
    
83.                 If i <> 5 Then
    
84.                     .Columns(i).HeaderCell.Style.Alignment = DataGridViewContentAlignment.MiddleRight
    
85.                     .Columns(i).DefaultCellStyle.Alignment = DataGridViewContentAlignment.MiddleRight
    
86.                     '// กรณีหลัก 5 เป็น CheckBox ให้จัดตำแหน่งตรงกึ่งกลางของเซลล์
    
87.                 Else
    
88.                     .Columns(i).HeaderCell.Style.Alignment = DataGridViewContentAlignment.MiddleCenter
    
89.                     .Columns(i).DefaultCellStyle.Alignment = DataGridViewContentAlignment.MiddleCenter
    
90.                 End If
    
91.             Next
    
92.             '/ Auto size column width of each main by sorting the field.
    
93.             .AutoSizeColumnsMode = DataGridViewAutoSizeColumnsMode.Fill
    
94.             '/ Adjust Header Styles
    
95.             With .ColumnHeadersDefaultCellStyle
    
96.                 .BackColor = Color.Crimson
    
97.                 .ForeColor = Color.White
    
98.                 .Font = New Font("Tahoma", 10, FontStyle.Bold)
    
99.             End With
    
100.             .ColumnHeadersHeightSizeMode = DataGridViewColumnHeadersHeightSizeMode.DisableResizing
     
101.             .ColumnHeadersHeight = 36
     
102.             '/ กำหนดให้ EnableHeadersVisualStyles = False เพื่อให้ยอมรับการเปลี่ยนแปลงสีพื้นหลังของ Header
     
103.             .EnableHeadersVisualStyles = False
     
104.         End With
     
105. 
     
106.     End Sub
     
107. 
     
108.     ' / --------------------------------------------------------------------------------
     
109.     ' / DATA SAMPLE ... ทำตัวอย่างให้ง่ายต่อการคำนวณ
     
110.     Private Sub FillDataSample()
     
111.         Try
     
112.             '/ Primary Key, Product ID, Product Name, Quantity, UnitPrice, ServiceCharge, Total
     
113.             Dim row As String() = New String() _
     
114.                 {"1", "PRO00001", "Product 1", "1", "1000.00", CBool(1), "0.00"}
     
115.             dgvData.Rows.Add(row)
     
116.             row = New String() _
     
117.                 {"2", "PRO00002", "Product 2", "1", "1000.00", CBool(0), "0.00"}
     
118.             dgvData.Rows.Add(row)
     
119.             row = New String() _
     
120.                 {"3", "PRO00003", "Product 3", "1", "1000.00", CBool(0), "0.00"}
     
121.             dgvData.Rows.Add(row)
     
122.         Catch ex As Exception
     
123.             MessageBox.Show(ex.Message)
     
124.         End Try
     
125.     End Sub
     
126. 
     
127.     ' / --------------------------------------------------------------------------------
     
128.     ' / Add new row
     
129.     Private Sub btnAddRow_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles btnAdd.Click
     
130.         Dim Position As Integer = dgvData.Rows.Count - 1
     
131.         Dim PK As Integer = 1   '/ Initialize value if without rows.
     
132.         '/ Get value at the last row
     
133.         Dim LastRow As New DataGridViewRow
     
134.         '/ ตรวจสอบค่าแถวสุดท้ายว่ามีค่า Primary Key เท่าไหร่ก็ให้บวก 1 (เป็นการจำลองการทำงาน โดยไม่ติดต่อกับ DataBase)
     
135.         '/ กรณีใช้ฐานข้อมูลจริงๆ ให้ตัดส่วนนี้ทิ้งแล้วใช้ Primary Key ของสินค้าจากฐานข้อมูลแทน
     
136.         If Position >= 0 Then
     
137.             '/ ไปแถวสุดท้าย
     
138.             LastRow = dgvData.Rows.OfType(Of DataGridViewRow).Last()
     
139.             '/ จากนั้นให้เพิ่มค่าขึ้น +1 (Column Index = 0)
     
140.             PK = LastRow.Cells(0).Value + 1
     
141.         End If
     
142.         Dim RandomClass As New Random()
     
143.         '/ Sample data
     
144.         '/ Primary Key, Product ID, Product Name, Quantity, UnitPrice, ServiceCharge, Total
     
145.         Dim row As String() = New String() {PK, "PRO0000" & PK, "Product " & PK, "1", Format(RandomClass.Next(100, 2000), "0.00"), RandomClass.Next(2) = 0, "0.00"}
     
146.         dgvData.Rows.Add(row)
     
147.         '/ โฟกัสไปที่ Column(3) หรือ Quantity (จำนวน)
     
148.         dgvData.CurrentCell = dgvData.Rows(dgvData.RowCount - 1).Cells(3)
     
149.         dgvData.Focus()
     
150. 
     
151.         '/ ไปคำนวณหาค่าผลรวม
     
152.         Call CalSumTotal()
     
153.     End Sub
     
154. 
     
155.     ' / --------------------------------------------------------------------------------
     
156.     ' / Remove select row
     
157.     Private Sub btnRemoveRow_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles btnRemove.Click
     
158.         If dgvData.RowCount = 0 Then Exit Sub
     
159.         '/
     
160.         dgvData.Rows.Remove(dgvData.CurrentRow)
     
161.         dgvData.Refresh()
     
162.         '/ เมื่อแถวรายการถูกลบออกไป และยังคงมีแถวรายการอยู่ ต้องไปคำนวณหาค่าผลรวมใหม่
     
163.         If dgvData.RowCount > 0 Then Call CalSumTotal()
     
164.     End Sub
     
165. 
     
166.     ' / --------------------------------------------------------------------------------
     
167.     ' / Calcualte sum of Total (Column Index = 6)
     
168.     ' / ทำทุกครั้งที่มีการเพิ่มหรือลบแถวรายการ และมีการเปลี่ยนแปลงค่าในเซลล์ Quantity, UnitPrice และ Service Charge
     
169.     Private Sub CalSumTotal()
     
170.         Dim ServiceCharge As Double = 0
     
171.         Dim NoneServiceCharge As Double = 0
     
172.         'txtTotal.Text = "0.00"
     
173.         'txtVat.Text = "0.00"
     
174.         'txtNetTotal.Text = "0.00"
     
175.         'txtServiceCharge.Text = "0.00"
     
176.         'txtServiceChargeSum.Text = "0.00"
     
177.         'txtNonServiceCharge.Text = "0.00"
     
178. 
     
179.         '// Set all TextBox Control to Zero.
     
180.         For Each tb As TextBox In Me.Controls.OfType(Of TextBox)()
     
181.             tb.Text = "0.00"
     
182.         Next
     
183.         '/ วนรอบตามจำนวนแถวที่มีอยู่ปัจจุบัน
     
184.         For nRow As Integer = 0 To dgvData.RowCount - 1
     
185.             '// หากติ๊กเครื่องหมายถูกหลักที่ 6 (Index = 5) จะคำนวณหาส่วนของสินค้า/บริการที่คิด Service Charge
     
186.             If CBool(dgvData.Rows(nRow).Cells(5).Value) Then
     
187.                 '// [จำนวน x ราคา]
     
188.                 ServiceCharge = Format(dgvData.Rows(nRow).Cells(3).Value * dgvData.Rows(nRow).Cells(4).Value, "#,##0.00")
     
189.                 '// รวมราคาที่คิด Service Charge เป็นค่าที่ยังไม่ได้คิด 10%
     
190.                 txtServiceCharge.Text = Format(CDbl(txtServiceCharge.Text) + ServiceCharge, "#,##0.00")
     
191.                 '// คิด Service Charge 10% ของราคา
     
192.                 ServiceCharge = ServiceCharge + (ServiceCharge * 10 / 100)
     
193.                 '// รวมจำนวนราคาและ Service Charge 10%
     
194.                 txtServiceChargeSum.Text = Format(CDbl(txtServiceChargeSum.Text) + ServiceCharge, "#,##0.00")
     
195. 
     
196.                 '// None Service Charge
     
197.             Else
     
198.                 NoneServiceCharge = Format(dgvData.Rows(nRow).Cells(3).Value * dgvData.Rows(nRow).Cells(4).Value, "#,##0.00")
     
199.                 txtNonServiceCharge.Text = Format(CDbl(txtNonServiceCharge.Text) + NoneServiceCharge, "#,##0.00")
     
200.             End If
     
201.             '/ หลักสุดท้ายของตารางกริด = [จำนวน x ราคา]
     
202.             dgvData.Rows(nRow).Cells(6).Value = Format(dgvData.Rows(nRow).Cells(3).Value * dgvData.Rows(nRow).Cells(4).Value, "#,##0.00")
     
203.         Next
     
204. 
     
205.         '// รวมราคาสินค้า/บริการ = Service Charge + None Service Charge
     
206.         Dim SumPrice As Double = Format(CDbl(txtServiceChargeSum.Text) + CDbl(txtNonServiceCharge.Text), "#,##0.00")
     
207.         '// TAX - การคิดภาษี
     
208.         Select Case cmbTax.SelectedIndex
     
209.             '// ไม่คิดภาษี
     
210.             Case 0
     
211.                 txtTotal.Text = Format(SumPrice, "#,##0.00")
     
212.                 txtVat.Text = "0.00"
     
213.                 '// รวมจำนวนเงินทั้งหมด
     
214.                 txtNetTotal.Text = Format(CDbl(txtTotal.Text) + CDbl(txtVat.Text), "#,##0.00")
     
215.                 '// หรือ txtNetTotal.Text = Format(SumPrice, "#,##0.00")
     
216.                 lblTotal.Text = "Total (1+2) :"
     
217.                 lblVat.Text = "None Vat : "
     
218.                 lblNetTotal.Text = "Net Total (Total) :"
     
219. 
     
220.                 '// รวมภาษี (Include Tax)
     
221.             Case 1
     
222.                 '// คิดภาษี 7% (Include VAT)
     
223.                 txtVat.Text = Format(SumPrice - (SumPrice / 1.07), "#,##0.00")
     
224.                 '// หาราคาสินค้าที่แท้จริง ... ราคาสินค้าทั้งหมดลบออกจากภาษี
     
225.                 txtTotal.Text = Format(SumPrice - CDbl(txtVat.Text), "#,##0.00")
     
226.                 '// รวมจำนวนเงินทั้งหมด
     
227.                 txtNetTotal.Text = Format(SumPrice, "#,##0.00")
     
228.                 lblTotal.Text = "Total (1+2-Vat) :"
     
229.                 lblVat.Text = "Include Vat (7%) : "
     
230.                 lblNetTotal.Text = "Net Total (Total+Vat) :"
     
231. 
     
232.                 '// แยกภาษี (Exclude Tax)
     
233.             Case 2
     
234.                 txtTotal.Text = Format(SumPrice, "#,##0.00")
     
235.                 '// คิดแยกภาษี 7% (Exclude VAT)
     
236.                 txtVat.Text = Format(CDbl(txtTotal.Text) * 7 / 100, "#,##0.00")
     
237.                 '// รวมจำนวนเงินทั้งหมด
     
238.                 txtNetTotal.Text = Format(CDbl(txtTotal.Text) + CDbl(txtVat.Text), "#,##0.00")
     
239.                 lblTotal.Text = "Total (1+2) :"
     
240.                 lblVat.Text = "Exclude Vat (7%) : "
     
241.                 lblNetTotal.Text = "Net Total (Total+Vat) :"
     
242.         End Select
     
243.     End Sub
     
244. 
     
245.     ' / --------------------------------------------------------------------------------
     
246.     ' / หลังจากการแก้ไขค่าในเซลล์และเกิดการกด Enter
     
247.     Private Sub dgvData_CellEndEdit(ByVal sender As Object, ByVal e As System.Windows.Forms.DataGridViewCellEventArgs) Handles dgvData.CellEndEdit
     
248.         '/ เกิดการเปลี่ยนแปลงค่าในหลัก Index ที่ 3 หรือ 4
     
249.         Select Case e.ColumnIndex
     
250.             Case 3, 4 '/ Column Index = 3 (Quantity), Column Index = 4 (UnitPrice)
     
251.                 '/ Quantity
     
252.                 '/ การดัก Error กรณีมีค่า Null Value ให้ใส่ค่า 0 ลงไปแทน
     
253.                 If IsDBNull(dgvData.Rows(e.RowIndex).Cells(3).Value) Then dgvData.Rows(e.RowIndex).Cells(3).Value = "0"
     
254.                 Dim Quantity As Integer = dgvData.Rows(e.RowIndex).Cells(3).Value
     
255. 
     
256.                 '/ UnitPrice
     
257.                 '/ If Null Value
     
258.                 If IsDBNull(dgvData.Rows(e.RowIndex).Cells(4).Value) Then dgvData.Rows(e.RowIndex).Cells(4).Value = "0.00"
     
259.                 dgvData.Rows(e.RowIndex).Cells(4).Value = Format(CDbl(dgvData.Rows(e.RowIndex).Cells(4).Value), "0.00")
     
260.                 Dim UnitPrice As Double = dgvData.Rows(e.RowIndex).Cells(4).Value
     
261.                 '/ Quantity x UnitPrice ในหลักที่ 7 (Index = 6)
     
262.                 dgvData.Rows(e.RowIndex).Cells(6).Value = (Quantity * UnitPrice).ToString("#,##0.00")
     
263.                 '/ Calculate Summary
     
264.                 Call CalSumTotal()
     
265.         End Select
     
266.     End Sub
     
267. 
     
268.     ' / --------------------------------------------------------------------------------
     
269.     ' / Validate Cell ... Quantity = Integer, UnitPrice = Double
     
270.     Private Sub dgvData_EditingControlShowing(ByVal sender As Object, ByVal e As System.Windows.Forms.DataGridViewEditingControlShowingEventArgs) Handles dgvData.EditingControlShowing
     
271.         Select Case dgvData.Columns(dgvData.CurrentCell.ColumnIndex).Name
     
272.             ' / Can use both Colume Index or Field Name
     
273.             Case "Quantity", "UnitPrice"
     
274.                 '/ Stop and Start event handler
     
275.                 RemoveHandler e.Control.KeyPress, AddressOf ValidKeyPress
     
276.                 AddHandler e.Control.KeyPress, AddressOf ValidKeyPress
     
277.         End Select
     
278.     End Sub
     
279. 
     
280.     ' / --------------------------------------------------------------------------------
     
281.     Private Sub ValidKeyPress(ByVal sender As System.Object, ByVal e As System.Windows.Forms.KeyPressEventArgs)
     
282.         Dim tb As TextBox = sender
     
283.         Select Case dgvData.CurrentCell.ColumnIndex
     
284.             Case 3  ' Quantity is Integer
     
285.                 Select Case e.KeyChar
     
286.                     Case "0" To "9"   ' digits 0 - 9 allowed
     
287.                     Case ChrW(Keys.Back)    ' backspace allowed for deleting (Delete key automatically overrides)
     
288. 
     
289.                     Case Else ' everything else ....
     
290.                         ' True = CPU cancel the KeyPress event
     
291.                         e.Handled = True ' and it's just like you never pressed a key at all
     
292.                 End Select
     
293. 
     
294.             Case 4  ' UnitPrice is Double
     
295.                 Select Case e.KeyChar
     
296.                     Case "0" To "9"
     
297.                         ' Allowed "."
     
298.                     Case "."
     
299.                         ' can present "." only one
     
300.                         If InStr(tb.Text, ".") Then e.Handled = True
     
301. 
     
302.                     Case ChrW(Keys.Back)
     
303.                         '/ Return False is Default value
     
304. 
     
305.                     Case Else
     
306.                         e.Handled = True
     
307. 
     
308.                 End Select
     
309.         End Select
     
310.     End Sub
     
311. 
     
312.     ' / --------------------------------------------------------------------------------
     
313.     '// เหตุการณ์ในการคลิ๊กเมาส์ลงในเซลล์ของหลักที่ 6 (Index = 5)
     
314.     Private Sub dgvData_CellContentClick(sender As Object, e As System.Windows.Forms.DataGridViewCellEventArgs) Handles dgvData.CellContentClick
     
315.         '// Column Index = 5
     
316.         If dgvData.Columns(e.ColumnIndex).Name = "chkServiceCharge" Then
     
317.             Dim isChecked As Boolean = dgvData.Rows(e.RowIndex).Cells(e.ColumnIndex).Value
     
318.             If isChecked = False Then
     
319.                 dgvData.Rows(e.RowIndex).Cells(e.ColumnIndex).Value = True
     
320.             Else
     
321.                 dgvData.Rows(e.RowIndex).Cells(e.ColumnIndex).Value = False
     
322.             End If
     
323.         End If
     
324.         '//
     
325.         '// คำนวณหาราคาใหม่
     
326.         Call CalSumTotal()
     
327.     End Sub
     
328. 
     
329.     Private Sub cmbTax_SelectedIndexChanged(sender As System.Object, e As System.EventArgs) Handles cmbTax.SelectedIndexChanged
     
330.         Call CalSumTotal()
     
331.     End Sub
     
332. 
     
333.     Private Sub frmServiceChargeVat_FormClosed(ByVal sender As Object, ByVal e As System.Windows.Forms.FormClosedEventArgs) Handles Me.FormClosed
     
334.         Me.Dispose()
     
335.         GC.SuppressFinalize(Me)
     
336.         Application.Exit()
     
337.     End Sub
     
338. 
     
339. End Class

คัดลอกไปที่คลิปบอร์ด

ดาวน์โหลดโค้ดฉบับเต็ม VB.NET (2010) ได้ที่นี่ ...