[VB.NET] การโหลดหลายๆชีตของไฟล์ Excel เพื่อนำมาแสดงผลลงใน ListView Control

thongkorn

การโหลดหลายๆชีตของไฟล์ Excel เพื่อนำมาแสดงผลลงใน Listview Control ซึ่งจะมีวิธีในการโหลดข้อมูลหลักๆอยู่ 2 แบบ คือ แบบแรกให้มอง Sheet เป็นเหมือนตารางข้อมูล ดังนั้นจึงต้องใช้ ADO.NET ทำการเชื่อมต่อเข้ากับไฟล์ Excel แบบที่ 2 คือมองเป็นไฟล์ Excel นั่นแหละ โดยใช้ Interop เข้าช่วย สำหรับโค้ดชุดนี้แอดมินจะเลือกวิธีแรกมาทำให้ดูเป็นตัวอย่างก่อน ...

หลักการมีอยู่ว่า 1 Sheet ก็เหมือนกับ 1 DataTable และหลายๆ DataTable จะรวมเข้ากันเป็น 1 DataSet ซึ่งก็จะถูกโหลดข้อมูลเข้ามาเก็บเอาไว้ในหน่วยความจำ และทำการตัดการเชื่อมต่อ หรือ Connection ออกไปได้เลย ... ก่อนที่เราจะนำข้อมูลมาใส่ลงใน ListView Control เราจะต้องลูปหาจำนวนหลัก (Column) และสร้างหลักขึ้นมาก่อนตามจำนวนที่มีอยู่ หรือ เราสามารถเลือกเฉพาะบางหลักที่อยู่ใน Excel มาสร้างเองเลยก็ได้ ...


มาดูโค้ดต้นฉบับกันเถอะ ...

1. Imports System.Data.OleDb
   
2. 
   
3. Public Class frmExcel2ListView
   
4.     '// ประกาศ Object DataSet
   
5.     Dim DS As DataSet = New DataSet()
   
6. 
   
7.     ' / --------------------------------------------------------------------------------
   
8.     ' / เลือกไฟล์ Excel
   
9.     ' / --------------------------------------------------------------------------------
   
10.     Private Sub btnOpenExcel_Click(sender As System.Object, e As System.EventArgs) Handles btnOpenExcel.Click
    
11.         '/ ประกาศใช้งาน Open File Dialog ในแบบ Run Time
    
12.         Dim dlgOpenFile As OpenFileDialog = New OpenFileDialog()
    
13.         ' / ตั้งค่าการใช้งาน Open File Dialog
    
14.         With dlgOpenFile
    
15.             .InitialDirectory = MyPath(Application.StartupPath)
    
16.             .Title = "เลือกไฟล์ MS Excel"
    
17.             .Filter = "XLSX Files (*.xlsx)|*.xlsx|XLS Files (*.xls)|*xls"
    
18.             .FilterIndex = 1
    
19.             .RestoreDirectory = True
    
20.         End With
    
21.         '/ หากเลือกปุ่ม OK หลังจากการ Browse ...
    
22.         If dlgOpenFile.ShowDialog() = DialogResult.OK Then
    
23.             txtFileName.Text = dlgOpenFile.FileName '// แสดงรายชื่อไฟล์ Excel และพาธ
    
24.             Dim strConn As String = _
    
25.                 " Provider=Microsoft.ACE.OLEDB.12.0;Data Source=" & dlgOpenFile.FileName & ";" & _
    
26.                 " Extended Properties=""Excel 12.0 Xml; HDR=YES"";"
    
27.             Try
    
28.                 Dim Conn As New System.Data.OleDb.OleDbConnection(strConn)
    
29.                 Conn.Open()
    
30.                 '//
    
31.                 cmbSheetName.Items.Clear()  '// เคลียร์ไอเทมใน ComboBox
    
32.                 ListView1.Columns.Clear()   '// เคลียร์หลักใน ListView เพื่อเริ่มต้นการแสดงผลใหม่
    
33.                 '// เคลียร์ค่า Table/Query ของเดิมใน DataSet ก่อนใช้งานใหม่
    
34.                 '// หรือหากให้เพิ่มตารางข้อมูล/คิวรี่ จากไฟล์อื่นเข้าไป ก็ตัดบรรทัดนี้ทิ้งออกไปได้เลย แต่ต้องเช็คว่ามีอยู่ใน DataSet แล้วหรือไม่
    
35.                 DS = New DataSet()
    
36.                 '/ มอง WorkSheet ให้เป็นเหมือนตารางข้อมูล (Table)
    
37.                 Dim dtSheets As System.Data.DataTable = Conn.GetOleDbSchemaTable(OleDbSchemaGuid.Tables, Nothing)
    
38.                 '/ วนลูปในแต่ละ Sheet ตามที่มีอยู่ เพื่อโหลดข้อมูลเข้าสู่ DataSet
    
39.                 For Each drSheet As DataRow In dtSheets.Rows
    
40.                     Dim sheetName As String = drSheet("TABLE_NAME").ToString()
    
41.                     '// นำรายชื่อ WorkSheet ทั้งหมด มาเก็บไว้ที่ ComboBox เพื่อรอให้ User เลือกนำไปใช้งาน
    
42.                     cmbSheetName.Items.Add(sheetName)
    
43.                     '// สร้าง Data Adapter เพื่อเก็บ Sheet ปัจจุบัน
    
44.                     Dim DA As New OleDbDataAdapter("SELECT * FROM [" & sheetName & "]", Conn)
    
45.                     '/ สร้าง DataTable เพื่อเก็บตารางข้อมูลจาก Sheet ปัจจุบัน
    
46.                     Dim DT As New System.Data.DataTable(sheetName)
    
47.                     '// นำข้อมูลจาก Sheet ไปเก็บไว้ใน DataTable
    
48.                     DA.Fill(DT)
    
49.                     '// นั่นก็คือเรานำ DataTable หลายๆตัวไปเก็บไว้ใน DataSet ได้ และจะอ้างอิงถึงตารางแต่ละตัวด้วยชื่อ Sheet
    
50.                     DS.Tables.Add(DT)
    
51.                     DA.Dispose()
    
52.                 Next
    
53.                 Conn.Close()
    
54.             Catch ex As Exception
    
55.                 ' Handle any exceptions that may occur during the process
    
56.                 MessageBox.Show("An error occurred: " & ex.Message)
    
57.             End Try
    
58.         End If
    
59.     End Sub
    
60. 
    
61.     ' / --------------------------------------------------------------------------------
    
62.     '// เลือก WorkSheet หรือ DataTable เพื่อแสดงผลข้อมูลลงใน ListView
    
63.     ' / --------------------------------------------------------------------------------
    
64.     Private Sub cmbSheetName_SelectedIndexChanged(sender As System.Object, e As System.EventArgs) Handles cmbSheetName.SelectedIndexChanged
    
65.         '// Initialize ListView.
    
66.         With ListView1
    
67.             .Clear()
    
68.             .View = View.Details
    
69.             .GridLines = True
    
70.             .FullRowSelect = True
    
71.             .HideSelection = False
    
72.             .MultiSelect = False
    
73.         End With
    
74.         Try
    
75.             '/ โหลดข้อมูล DataTable แต่ละตัว ตามชื่อที่มีอยู่ใน DataSet
    
76.             Dim DT As DataTable = DS.Tables(cmbSheetName.Text)
    
77.             '// อ่านจำนวนหลักทั้งหมดเข้ามาก่อนเพื่อสร้าง Column ให้กับ ListView
    
78.             For iCol = 0 To DT.Columns.Count - 1
    
79.                 ListView1.Columns.Add(DT.Columns(iCol).ColumnName)
    
80.             Next
    
81.             '// เมื่อมีหลัก (Column) เรียบร้อยแล้ว ต่อไปก็อ่านข้อมูลในแต่ละแถว (Row) เข้ามา
    
82.             For sRow = 0 To DT.Rows.Count - 1
    
83.                 Dim LV As New ListViewItem
    
84.                 Dim dRow As DataRow = DT.Rows(sRow)
    
85.                 LV = ListView1.Items.Add(dRow.Item(0))  '// --> Primary Node
    
86.                 For iCol = 1 To DT.Columns.Count - 1
    
87.                     LV.SubItems.Add(dRow(iCol).ToString())
    
88.                 Next
    
89.             Next
    
90.             '// ปรับความกว้างของ Column ในการแสดงผลบน ListView
    
91.             ListView1.AutoResizeColumns(ColumnHeaderAutoResizeStyle.HeaderSize)
    
92.         Catch ex As Exception
    
93.             MessageBox.Show(ex.Message)
    
94.         End Try
    
95.     End Sub
    
96. 
    
97.     ' / --------------------------------------------------------------------------------
    
98.     ' / เหตุการณ์ Double Click Mouse บน ListView เพื่อแสดงผลข้อมูลในแถวรายการที่เลือก
    
99.     ' / --------------------------------------------------------------------------------
    
100.     Private Sub ListView1_DoubleClick(sender As Object, e As System.EventArgs) Handles ListView1.DoubleClick
     
101.         MessageBox.Show( _
     
102.             "Column 0: " & ListView1.SelectedItems(0).Text & vbCrLf & _
     
103.             "Column 1: " & ListView1.SelectedItems.Item(0).SubItems(1).Text & vbCrLf & _
     
104.             "Column 2: " & ListView1.SelectedItems.Item(0).SubItems(2).Text & vbCrLf & _
     
105.             "Column 3: " & ListView1.SelectedItems.Item(0).SubItems(3).Text)
     
106.     End Sub
     
107. 
     
108.     Private Sub txtFileName_KeyPress(sender As Object, e As System.Windows.Forms.KeyPressEventArgs) Handles txtFileName.KeyPress
     
109.         e.Handled = True    '// Can't press any key into TextBox Control.
     
110.     End Sub
     
111. 
     
112.     Private Sub btnExit_Click(sender As System.Object, e As System.EventArgs) Handles btnExit.Click
     
113.         Me.Close()
     
114.     End Sub
     
115. 
     
116.     Private Sub frmExcel2ListView_FormClosed(sender As Object, e As System.Windows.Forms.FormClosedEventArgs) Handles Me.FormClosed
     
117.         Me.Dispose()
     
118.         System.Windows.Forms.Application.Exit()
     
119.     End Sub
     
120. 
     
121. #Region "FUNCTION"
     
122.     ' / --------------------------------------------------------------------------------
     
123.     ' / Get my project path
     
124.     ' / AppPath = C:\My Project\bin\debug
     
125.     ' / Replace "\bin\debug" with ""
     
126.     ' / Return : C:\My Project\
     
127.     Public Function MyPath(ByVal AppPath As String) As String
     
128.         '/ MessageBox.Show(AppPath);
     
129.         MyPath = AppPath.ToLower.Replace("\bin\debug", "").Replace("\bin\release", "").Replace("\bin\x86\debug", "").Replace("\bin\x86\release", "")
     
130.         '// If not found folder then put the \ (BackSlash) or ASCII Code = 92 at the end.
     
131.         '/ Return Value
     
132.         If Microsoft.VisualBasic.Right(MyPath, 1) <> Chr(92) Then MyPath = MyPath & Chr(92)
     
133.     End Function
     
134. 
     
135. #End Region
     
136. 
     
137. End Class

คัดลอกไปที่คลิปบอร์ด

ดาวน์โหลดโค้ดต้นฉบับ VB.NET (2010) ได้จากที่นี่ ...