[VB6] การตรวจสอบข้อมูล (Validate Data) สำหรับ TextBox Control

thongkorn

การตรวจสอบข้อมูล หรือ Validate Data เป็นส่วนสำคัญอย่างมาก ในการดัก Error โดยเฉพาะค่าทางตัวเลข เพราะเราจะดักค่า หรือเช็คความถูกต้องก่อนที่จะนำค่าไปคำนวณผล โดยที่ไม่ต้องมาใช้คำสั่ง IF ซ้อนๆกัน และเหตุการณ์ที่ต้องทำซ้ำๆ ด้งนั้นเราควรจะนำโค้ดไปเก็บไว้ในลักษณะของ Public Function (รับค่าและคืนค่าได้) เพื่อให้ฟอร์มทุกฟอร์มมองเห็นได้ และลดจำนวนโค้ดลงไป ในโค้ดชุดนี้แอดมินได้เพิ่มเรื่องของการทำไฮไลท์เพื่อแสดงตำแหน่งโฟกัสการป้อนข้อมูล และที่สำคัญคือการแก้ปัญหาในเรื่องการกด Enter ในการเลื่อนตำแหน่งโฟกัส ซึ่งจะมีปัญหามาตั้งแต่ Windows 8+ ทำให้เกิด Error หรือที่เรียกว่า Permission Denied (Run Time Error 70)


การทำไฮไลท์ให้กับตำแหน่งโฟกัส


เทคนิคการเรียงลำดับ TabIndex


ควรย้ายฟังค์ชั่นเหล่านี้ให้ไปอยู่ในโมดูล และประกาศเป็นแบบ Public

มาดูโค้ดฉบับเต็มกันเถอะ ...

1. Option Explicit
   
2. 
   
3. ' / ---------------------------------------------------------------------------
   
4. Private Sub Form_Load()
   
5. ' / ---------------------------------------------------------------------------
   
6.     '/ เคลียร์ค่าใน TextBox ทั้งหมด
   
7.     txtAlphabet.Text = ""
   
8.     txtAlphabetUCase.Text = ""
   
9.     txtInteger.Text = "0"
   
10.     txtDouble.Text = "0.00"
    
11.     '/ จัดเรียงลำดับของการโฟกัส หรือ TabIndex (ไปทำในตอน Designer จะง่ายกว่า)
    
12.     txtAlphabet.TabIndex = 0
    
13.     txtAlphabetUCase.TabIndex = 1
    
14.     txtInteger.TabIndex = 2
    
15.     txtDouble.TabIndex = 3
    
16. End Sub
    
17. 
    
18. ' / ---------------------------------------------------------------------------
    
19. ' / เหตุการณ์ในการที่ TextBox ได้รับโฟกัส
    
20. Private Sub txtAlphabet_GotFocus()
    
21. ' / ---------------------------------------------------------------------------
    
22.     '/ ทำไฮไลท์แถบแสง โดยเรียกไปยังฟังค์ชั่น HLText และส่งชื่อ Control ไปด้วย
    
23.     Call HLText(txtAlphabet)
    
24. End Sub
    
25. 
    
26. ' / ---------------------------------------------------------------------------
    
27. Private Sub txtAlphabet_KeyPress(KeyAscii As Integer)
    
28. ' / ---------------------------------------------------------------------------
    
29.     ' / หากเกิดการกด Enter ให้ส่งคีย์ TAB เพื่อเลื่อนตำแหน่งโฟกัสไปยัง Control ถัดไป
    
30.     ' / VB6 ไม่มีเหตุการณ์กด Enter แล้วเลื่อนโฟกัส ต้องใช้การส่งคีย์ (SendKeys) การกด TAB แทน
    
31.     If KeyAscii = 13 Then
    
32.         Sendkeys "{TAB}"
    
33.         KeyAscii = 0    '/ ปิดเสียง
    
34.     Else
    
35.         '/ ส่งค่า KeyAscii ที่กดลงไปบนคีย์แต่ละตัว ไปให้กับฟังค์ชั่น CheckAlphabet และส่งค่ากลับคืนมา
    
36.         '/ หากเป็นตัวอักษรภาษาอังกฤษก็จะคืนค่า Ascii Code A - Z (65 - 90), a - z (97 - 122)
    
37.         '/ หากไม่ใช่ ก็จะคืนค่า 0 กลับมา เสมือนว่าไม่มีการกดคีย์ใดๆเลย
    
38.         KeyAscii = CheckAlphabet(KeyAscii)
    
39.     End If
    
40. End Sub
    
41. 
    
42. ' / ---------------------------------------------------------------------------
    
43. ' / เหตุการณ์ในการที่ TextBox ได้รับโฟกัส
    
44. Private Sub txtAlphabetUCase_GotFocus()
    
45. ' / ---------------------------------------------------------------------------
    
46.     '/ ทำไฮไลท์แถบแสง โดยเรียกไปยังฟังค์ชั่น HLText และส่งชื่อ Control ไปด้วย
    
47.     Call HLText(txtAlphabetUCase)
    
48. End Sub
    
49. 
    
50. ' / ---------------------------------------------------------------------------
    
51. Private Sub txtAlphabetUCase_KeyPress(KeyAscii As Integer)
    
52. ' / ---------------------------------------------------------------------------
    
53.     ' / หากเกิดการกด Enter ให้ส่งคีย์ TAB เพื่อเลื่อนตำแหน่งโฟกัสไปยัง Control ถัดไป
    
54.     If KeyAscii = 13 Then
    
55.         Sendkeys "{TAB}"
    
56.         KeyAscii = 0    '/ ปิดเสียง
    
57.     Else
    
58.         '/ รับค่าตัวอักษรภาษาอังกฤษทั้งตัวใหญตัวเล็ก แต่กดตัวอักษรตัวเล็ก a - z จะแปลงเป็นตัวอักษรตัวใหญ่ A - Z ให้อัตโนมัติ
    
59.         KeyAscii = Asc(UCase(Chr(CheckAlphabet(KeyAscii))))
    
60.     End If
    
61. End Sub
    
62. 
    
63. ' / ---------------------------------------------------------------------------
    
64. ' / เหตุการณ์ในการที่ TextBox ได้รับโฟกัส
    
65. Private Sub txtDouble_GotFocus()
    
66. ' / ---------------------------------------------------------------------------
    
67.     '/ ทำไฮไลท์แถบแสง โดยเรียกไปยังฟังค์ชั่น HLText และส่งชื่อ Control ไปด้วย
    
68.     Call HLText(txtDouble)
    
69. End Sub
    
70. 
    
71. ' / ---------------------------------------------------------------------------
    
72. Private Sub txtDouble_KeyPress(KeyAscii As Integer)
    
73. ' / ---------------------------------------------------------------------------
    
74.     ' / หากเกิดการกด Enter ให้ส่งคีย์ TAB เพื่อเลื่อนตำแหน่งโฟกัสไปยัง Control ถัดไป
    
75.     If KeyAscii = 13 Then
    
76.         Sendkeys "{TAB}"
    
77.         KeyAscii = 0    '/ ปิดเสียง
    
78.     Else
    
79.         '/ ส่งค่า KeyAscii ที่กดลงไปบนคีย์แต่ละตัว ไปให้กับฟังค์ชั่น CheckAlphabet และส่งค่ากลับคืนมา
    
80.         '/ หากเป็นตัวอักษรภาษาอังกฤษก็จะคืนค่า Ascii Code A - Z (65 - 90), a - z (97 - 122)
    
81.         '/ หากไม่ใช่ ก็จะคืนค่า 0 กลับมา เสมือนว่าไม่มีการกดคีย์ใดๆเลย
    
82.         KeyAscii = CheckCurrency(KeyAscii, txtDouble)
    
83.     End If
    
84. End Sub
    
85. 
    
86. ' / ---------------------------------------------------------------------------
    
87. ' / เหตุการณ์ที่ TextBox หลุดโฟกัสไป
    
88. Private Sub txtDouble_LostFocus()
    
89. ' / ---------------------------------------------------------------------------
    
90.     '/ ป้องกันค่าว่าง ก่อนที่จะนำค่าไปเก็บหรือคำนวณ
    
91.     If Trim(txtDouble.Text) = "" Then
    
92.         txtDouble.Text = "0.00"
    
93.     Else
    
94.         '/ จัดรูปแบบให้กับค่าตัวเลขแบบทศนิยม
    
95.         txtDouble.Text = Format(CDbl(txtDouble.Text), "0.00")
    
96.     End If
    
97. End Sub
    
98. 
    
99. ' / ---------------------------------------------------------------------------
    
100. ' / เหตุการณ์ในการที่ TextBox ได้รับโฟกัส
     
101. Private Sub txtInteger_GotFocus()
     
102. ' / ---------------------------------------------------------------------------
     
103.     '/ ทำไฮไลท์
     
104.     Call HLText(txtInteger)
     
105. End Sub
     
106. 
     
107. ' / ---------------------------------------------------------------------------
     
108. ' / เหตุการณ์ที่ TextBox หลุดโฟกัสไป
     
109. Private Sub txtInteger_LostFocus()
     
110. ' / ---------------------------------------------------------------------------
     
111.     '/ ป้องกันค่าว่าง ก่อนที่จะนำค่าไปเก็บหรือคำนวณ
     
112.     If Trim(txtInteger.Text) = "" Then
     
113.         txtInteger.Text = "0"
     
114.     Else
     
115.         '/ จัดรูปแบบให้กับค่าตัวเลขแบบจำนวนเต็ม
     
116.         txtInteger.Text = Format(CInt(txtInteger.Text), "0")
     
117.     End If
     
118. End Sub
     
119. 
     
120. ' / ---------------------------------------------------------------------------
     
121. ' / โปรแกรมย่อยเหตุการณ์ (Event) ในการรับค่าการกดคีย์บนแป้นคีย์บอร์ดทีละตัว
     
122. Private Sub txtInteger_KeyPress(KeyAscii As Integer)
     
123. '/ ---------------------------------------------------------------------------
     
124.     ' / หากเกิดการกด Enter ให้ส่งคีย์ TAB เพื่อเลื่อนตำแหน่งโฟกัสไปยัง Control ถัดไป
     
125.     If KeyAscii = 13 Then
     
126.         Sendkeys "{TAB}"
     
127.         KeyAscii = 0    '/ ปิดเสียง
     
128.     Else
     
129.         '/ ส่งค่า KeyAscii ที่กดลงไปบนคีย์แต่ละตัว ไปให้กับฟังค์ชั่น CheckDigitOnly และส่งค่ากลับมา
     
130.         '/ หากเป็นตัวเลขก็จะคืนค่า Ascii Code 48 - 57 (หรือคีย์ 0 - 9) กลับคืนมา
     
131.         '/ หากไม่ใช่ ก็จะคืนค่า 0 กลับมา เสมือนว่าไม่มีการกดคีย์ใดๆเลย
     
132.         KeyAscii = CheckDigitOnly(KeyAscii)
     
133.     End If
     
134. End Sub
     
135. 
     
136. ' / ---------------------------------------------------------------------------
     
137. ' / ฟังค์ชั่นในการทำไฮไลท์เมื่อ TextBox ถูก Focus
     
138. ' / ---------------------------------------------------------------------------
     
139. Public Sub HLText(ByRef sText)
     
140.     On Error Resume Next
     
141.     With sText
     
142.         .SelStart = 0
     
143.         .SelLength = Len(sText.Text)
     
144.     End With
     
145. End Sub
     
146. 
     
147. ' / ---------------------------------------------------------------------------
     
148. ' / แก้ปัญหาเรื่อง SendKeys ตั้งแต่ Windows 8+
     
149. Public Sub Sendkeys(Text As String, Optional Wait As Boolean = False)
     
150. ' / ---------------------------------------------------------------------------
     
151.     Dim WshShell As Object
     
152.     Set WshShell = CreateObject("Wscript.shell")
     
153.     WshShell.Sendkeys Text, Wait
     
154.     Set WshShell = Nothing
     
155. End Sub
     
156. 
     
157. ' / ---------------------------------------------------------------------------
     
158. ' / ฟังค์ชั่นในการตรวจสอบว่าคีย์ที่กดลงไปนั้นมันเป็น 0 - 9 หรือไม่
     
159. ' / รับค่า KeyAscii จาก TextBox เข้ามาทีละตัว และเช็คค่า ASCII Code
     
160. ' / หากเป็นตัวเลขก็คืนค่าตัวมันเองกลับ ก็คือยอมรับการกดคีย์นั่นเอง
     
161. ' / หากไม่ใช่ก็คืนค่ากลับเป็น 0 เสมือนไม่มีการกดคีย์ใดๆนั่นเอง
     
162. Public Function CheckDigitOnly(ByVal Index As Integer) As Integer
     
163. '/ ---------------------------------------------------------------------------
     
164.         Select Case Index
     
165.             '/ ASCII Code หากมีค่า 48 - 57 ก็คือเลข 0 - 9 ก็คืนค่าตัวมันเองกลับไป
     
166.             Case 48 To 57
     
167.             Case 8, 13 ' Backspace = 8, Enter = 13
     
168.             '/ หากไม่ใช่คีย์ที่กดใน 2 Case ด้านบน ก็คืนค่า 0 กลับไป เสมือนว่าไม่มีการกดคีย์ใดๆ
     
169.             Case Else
     
170.                 Index = 0
     
171.         End Select
     
172.         CheckDigitOnly = Index
     
173. End Function
     
174. 
     
175. '/ ---------------------------------------------------------------------------
     
176. ' / ฟังค์ชั่นในการตรวจสอบว่าคีย์ที่กดลงไปนั้นมันเป็น 0 - 9 และ . หรือไม่
     
177. ' / และเครื่องหมายจุด (.) จะรับได้เพียงค่าเดียวเท่านั้น
     
178. Public Function CheckCurrency(Index As Integer, Ctrl As TextBox) As Integer
     
179. '/ ---------------------------------------------------------------------------
     
180.     Select Case Index
     
181.             ' 0 - 9 and Return index = KeyAscii
     
182.         Case 48 To 57
     
183.             ' Back Space and Return index = KeyAscii
     
184.         Case 8
     
185.             ' Enter and Return index = KeyAscii
     
186.         Case 13
     
187.         Case 46 ' รหัส Ascii Code  ของเครื่องหมายจุด
     
188.             If InStr(Ctrl, ".") Then Index = 0 '/ ใช้ฟังค์ชั่น InStr (In String) เพื่อหาเครื่องหมายจุดใน TextBox
     
189.         Case Else
     
190.             Index = 0
     
191.     End Select
     
192.     CheckCurrency = Index ' Return ค่ากลับตามที่ได้ตรวจสอบ
     
193. End Function
     
194. 
     
195. '/ ---------------------------------------------------------------------------
     
196. ' / ฟังค์ชั่นในการรับค่าตัวอักษรภาษาอังกฤษเท่านั้น
     
197. '/ ---------------------------------------------------------------------------
     
198. Public Function CheckAlphabet(Index As Integer) As Integer
     
199.     Select Case Index
     
200.         '/ ASCII Code A - Z (65 - 90), a - z (97 - 122)
     
201.         Case 65 To 90, 97 To 122 '/ หรือค่าอื่นๆที่เราต้องการ , Asc(" "), Asc("-"), Asc("&"), Asc("."), Asc("*"), Asc("[        DISCUZ_CODE_0        ]quot;), Asc("/"), Asc("+"), Asc("%")
     
202.             CheckAlphabet = Index
     
203.         '/ Back Space
     
204.         Case 8
     
205.         '/ Enter
     
206.         Case 13
     
207.         'Case 42 ' *
     
208.         'Case 43 ' +
     
209.         'Case 45 ' -
     
210.         'Case 46 ' .
     
211.         'Case 47 ' /
     
212.         Case Else
     
213.             Index = 0
     
214.     End Select
     
215.     '/ Return ค่ากลับ
     
216.     CheckAlphabet = Index
     
217. End Function

คัดลอกไปที่คลิปบอร์ด

ดาวน์โหลดโค้ด VB6 (SP1) ฉบับเต็มได้จากที่นี่ ...