[VB.NET] โค้ดการเปิดหลายๆโฟลเดอร์แบบอัตโนมัติ

thongkorn

หน้าจอ GUI (Graphics User Interface) สามารถเปิดโฟลเดอร์ได้หลายๆโฟลเดอร์แบบ Manual และ Automatic


การทำ Registry เพื่อสั่งให้รันโปรแกรมตอนที่ Start Windows
Registry: Computer\HKEY_CURRENT_USER\SOFTWARE\Microsoft\Windows\CurrentVersion\Run

โค้ดโปรแกรมชุดนี้มีจุดประสงค์ก็เพื่อต้องการให้ ทำการเปิดหลายๆโฟลเดอร์ได้ทั้งแบบ Manual (กดปุ่มเปิดเอาเอง) และการเปิดโฟลเดอร์แบบอัตโนมัติ ตอนที่สตาร์ทวินโดวส์เข้ามาทุกครั้ง ซึ่งจะอาศัยการกำหนดค่าใน Registry เอาไว้ โฟลเดอร์ที่ถูกเลือกจะถูกเก็บเอาไว้ใน Config.ini ซึ่งแอดมินจะใช้โค้ด Win32API ในการอ่านและเขียนค่าเข้าไปในไฟล์  INI ...

มาดูโค้ดฉบับเต็มกันเถอะ ... (frmOpenMultipleFolder.vb)

1. Imports System.IO
   
2. Imports System.Runtime.InteropServices
   
3. Imports System.Text
   
4. Imports Microsoft.Win32
   
5. 
   
6. Public Class frmOpenMultipleFolder
   
7.     '// กำหนด Icon ให้กับ ListView
   
8.     Private imgList As New ImageList()
   
9. 
   
10.     '// ไฟล์ Config.ini จะเป็นไฟล์ที่เก็บตำแหน่งของโฟลเดอร์ต่างๆ
    
11.     Private iniPath As String = MyPath(Application.StartupPath) & "Config.ini"
    
12. 
    
13.     '// สร้าง CheckBox แบบ Run Time เพื่อกำหนดให้รันโปรแกรมตอน Start Windows
    
14.     Dim chkStartup As New CheckBox()
    
15. 
    
16.     '// การจัดเรียงใน ListView ด้วยการเก็บคอลัมน์ล่าสุดที่กดกับลำดับการเรียง
    
17.     Private SortColumn As Integer = -1
    
18.     Private SortOrder As SortOrder = SortOrder.None
    
19. 
    
20.     '// เพิ่มเติมข้อมูล
    
21.     '// Win32 API (Application Programming Interface) คือ ชุดฟังก์ชั่นพื้นฐานที่ Microsoft จัดเตรียมไว้สำหรับนักพัฒนาเพื่อโต้ตอบกับระบบปฏิบัติการ Windows โดยตรง เป็นการทำงานระดับต่ำ (Low-level Access) ดังนั้นมันจึงทำงานได้เร็ว และมีประสิทธิภาพสูง
    
22.     '// แปลเป็นไทยง่ายๆว่า การดึงพลังและขีดความสามารถของ Windows ออกมาใช้งานได้อย่างเต็มที่นั่นเอง
    
23. 
    
24. #Region "INI API"
    
25.     '// --------------------------------------------------------------------------------------
    
26.     '// APIs for Read/Write INI File.
    
27.     <DllImport("kernel32", CharSet:=CharSet.Unicode)>
    
28.     Private Shared Function WritePrivateProfileString(lpAppName As String, lpKeyName As String, lpString As String, lpFileName As String) As Long
    
29.     End Function
    
30. 
    
31.     <DllImport("kernel32", CharSet:=CharSet.Unicode)>
    
32.     Private Shared Function GetPrivateProfileString(lpAppName As String, lpKeyName As String, lpDefault As String,
    
33.         lpReturnedString As StringBuilder, nSize As Integer, lpFileName As String) As Integer
    
34.     End Function
    
35. 
    
36.     Private Sub WriteIni(section As String, key As String, value As String, filePath As String)
    
37.         WritePrivateProfileString(section, key, value, filePath)
    
38.     End Sub
    
39. 
    
40.     Private Function ReadIni(section As String, key As String, defaultValue As String, filePath As String) As String
    
41.         Dim sb As New StringBuilder(1024)
    
42.         Dim count As Integer = GetPrivateProfileString(section, key, defaultValue, sb, sb.Capacity, filePath)
    
43.         If count > 0 Then
    
44.             Return sb.ToString().Trim
    
45.         Else
    
46.             Return ""
    
47.         End If
    
48.     End Function
    
49. #End Region
    
50. 
    
51. #Region "ICON API"
    
52.     '// ------------------------------------------------ APIs ดึงไอคอนมาใช้งาน ------------------------------------------------
    
53.     <DllImport("shell32.dll", CharSet:=CharSet.Auto)>
    
54.     Private Shared Function SHGetFileInfo(pszPath As String, dwFileAttributes As UInteger, ByRef psfi As SHFILEINFO,
    
55.                                           cbFileInfo As UInteger, uFlags As UInteger) As IntPtr
    
56.     End Function
    
57. 
    
58.     <StructLayout(LayoutKind.Sequential, CharSet:=CharSet.Auto)>
    
59.     Private Structure SHFILEINFO
    
60.         Public hIcon As IntPtr
    
61.         Public iIcon As Integer
    
62.         Public dwAttributes As UInteger
    
63.         <MarshalAs(UnmanagedType.ByValTStr, SizeConst:=260)>
    
64.         Public szDisplayName As String
    
65.         <MarshalAs(UnmanagedType.ByValTStr, SizeConst:=80)>
    
66.         Public szTypeName As String
    
67.     End Structure
    
68. 
    
69.     Private Const SHGFI_ICON As UInteger = &H100
    
70.     Private Const SHGFI_SMALLICON As UInteger = &H1
    
71. 
    
72.     '// ดึงไอคอนโฟลเดอร์
    
73.     Private Function GetFolderIcon(path As String) As Icon
    
74.         Dim shinfo As New SHFILEINFO()
    
75.         SHGetFileInfo(path, 0, shinfo, CUInt(Marshal.SizeOf(shinfo)), SHGFI_ICON Or SHGFI_SMALLICON)
    
76.         Return Icon.FromHandle(shinfo.hIcon)
    
77.     End Function
    
78. #End Region
    
79. 
    
80.     '// --------------------------------------------------------------------------------------
    
81.     '// S T A R T . . . H E R E
    
82.     '// --------------------------------------------------------------------------------------
    
83.     Private Sub frmOpenMultipleFolder_Load(sender As Object, e As EventArgs) Handles MyBase.Load
    
84.         '// ImageList สำหรับ Icon
    
85.         imgList.ImageSize = New Size(18, 22)    '// จะมีผลต่อความสูงของแถวในตัว ListView
    
86.         imgList.ColorDepth = ColorDepth.Depth32Bit
    
87.         lvwFolder.SmallImageList = imgList
    
88. 
    
89.         '// ตั้งค่าให้กับ CheckBox เพื่อให้พื้นหลังกลมกลืนกับ ToolStrip
    
90.         chkStartup.Text = "Run on Windows Startup"
    
91.         chkStartup.Font = New Font("Tahoma", 10, FontStyle.Regular)
    
92.         chkStartup.BackColor = Color.Transparent
    
93.         Dim host As New ToolStripControlHost(chkStartup)
    
94.         ToolStrip1.Items.Add(host)
    
95.         '// Add Event Handler เพื่อกำหนดค่าการเปิดโฟลเดอร์อัตโนมัติ เมื่อ Start Windows
    
96.         AddHandler chkStartup.CheckedChanged, AddressOf chkStartup_CheckedChanged
    
97. 
    
98.         '// โค้ดที่เกี่ยวข้องจะอยู่ที่ Region "LISTVIEW"
    
99.         '// TIPS: ใช้เมื่อต้องการการแสดงผลที่พิเศษกว่าเดิม เช่น เปลี่ยนสีแต่ละแถวสลับกัน หรือใส่รูปภาพหรือไอคอนพิเศษ
    
100.         lvwFolder.OwnerDraw = True
     
101.         '// ตั้งค่าให้กับ ListView
     
102.         Call InitializeListView()
     
103.         '// โหลดรายการที่เก็บเอาไว้มาจากไฟล์ Config.ini
     
104.         Call LoadConfig()
     
105. 
     
106.         '// -------------------------------------------- IMPORTANT --------------------------------------------
     
107.         '// Computer\HKEY_CURRENT_USER\SOFTWARE\Microsoft\Windows\CurrentVersion\Run
     
108.         '// ทดสอบการกำหนดให้ Run ตอน Start Windows
     
109.         If IsStartupEnabled() Then
     
110.             tsbOpenFolder.PerformClick()    '// สั่งโปรแกรมให้เปิดโฟลเดอร์
     
111.             chkStartup.Checked = True
     
112.         Else
     
113.             chkStartup.Checked = False
     
114.         End If
     
115.         '// --------------------------------------------------------------
     
116.     End Sub
     
117. 
     
118.     '// --------------------------------------------------------------------------------------
     
119.     '// Add Event Handler เพื่อกำหนดให้โปรแกรมทำงานตอน Start Windows หรือไม่
     
120.     '// --------------------------------------------------------------------------------------
     
121.     Private Sub chkStartup_CheckedChanged(sender As System.Object, e As System.EventArgs)
     
122.         If chkStartUp.Checked Then
     
123.             '// Run on Windows Start
     
124.             Call SetStartup(True)
     
125.         Else
     
126.             Call SetStartup(False)
     
127.         End If
     
128.     End Sub
     
129. 
     
130.     '// ============= สร้างค่าใน Registry เพื่อให้รันตอน Startup =============
     
131.     '// หาก enable กำหนดเป็น True จะทำการ Registry เพื่อให้โปรแกรม Run ตอน Start Windows
     
132.     '// หาก enable กำหนดเป็น False จะทำการลบ Registry ออกไป
     
133.     '// Computer\HKEY_CURRENT_USER\SOFTWARE\Microsoft\Windows\CurrentVersion\Run
     
134.     Private Sub SetStartup(enable As Boolean)
     
135.         Try
     
136.             Using key As RegistryKey = Registry.CurrentUser.OpenSubKey(
     
137.                 "Software\Microsoft\Windows\CurrentVersion\Run", True)
     
138.                 If key Is Nothing Then
     
139.                     MessageBox.Show("ไม่สามารถเข้าถึง Registry ได้", "รายงานความผิดพลาด", MessageBoxButtons.OK, MessageBoxIcon.Error)
     
140.                     Return
     
141.                 End If
     
142.                 If enable Then
     
143.                     key.SetValue("OpenMultipleFolder", Application.ExecutablePath)
     
144.                 Else
     
145.                     '// ลบค่าออก ถ้าไม่ต้องการให้รันอัตโนมัติ
     
146.                     If key.GetValue("OpenMultipleFolder") IsNot Nothing Then key.DeleteValue("OpenMultipleFolder")
     
147.                 End If
     
148.             End Using
     
149.         Catch ex As Exception
     
150.             MessageBox.Show("เกิดข้อผิดพลาดในการตั้งค่า Startup: " & ex.Message, "รายงานความผิดพลาด", MessageBoxButtons.OK, MessageBoxIcon.Error)
     
151.         End Try
     
152.     End Sub
     
153. 
     
154.     '// ---------------------- ทดสอบค่า Run on Windows Start ----------------------
     
155.     Private Function IsStartupEnabled() As Boolean
     
156.         Try
     
157.             Using key As RegistryKey = Registry.CurrentUser.OpenSubKey(
     
158.                 "Software\Microsoft\Windows\CurrentVersion\Run", False) '// อ่านอย่างเดียว (ReadOnly)
     
159.                 If key Is Nothing Then Return False '// ไม่สามารถเปิด Registry ได้ (ถือว่าไม่ได้ตั้งค่า)
     
160. 
     
161.                 '// ตรวจสอบว่ามีค่า "OpenMultipleFolder" หรือไม่
     
162.                 Dim value As Object = key.GetValue("OpenMultipleFolder")
     
163.                 If value IsNot Nothing Then
     
164.                     '// ตรวจสอบว่าค่าที่เก็บเป็นพาธของโปรแกรมตัวเองหรือไม่
     
165.                     Dim ProgramPath As String = Application.ExecutablePath
     
166.                     Dim RegistryPath As String = value.ToString()
     
167. 
     
168.                     '// เปรียบเทียบแบบไม่สนใจตัวพิมพ์ใหญ่/เล็ก และตัด quote ออกถ้ามี
     
169.                     Dim CleanRegistryPath As String = RegistryPath.Replace("""", "")
     
170.                     Return String.Equals(CleanRegistryPath, ProgramPath, StringComparison.OrdinalIgnoreCase)
     
171.                 Else
     
172.                     Return False
     
173.                 End If
     
174.             End Using
     
175.         Catch ex As Exception
     
176.             '// ถ้าเกิดข้อผิดพลาด เช่น สิทธิ์ไม่พอ ถือว่าไม่ได้ตั้งค่า รีเทิร์นค่า False กลับไป
     
177.             'MessageBox.Show("Error checking startup: " & ex.Message)
     
178.             Return False
     
179.         End Try
     
180.     End Function
     
181. 
     
182.     '// ---------------------- ตั้งค่าเริ่มต้นให้กับ ListView Control ----------------------
     
183.     Private Sub InitializeListView()
     
184.         With lvwFolder
     
185.             .View = View.Details
     
186.             .MultiSelect = False
     
187.             .HideSelection = False
     
188.             .FullRowSelect = True
     
189.             .GridLines = True
     
190.             .Columns.Clear()
     
191.             .Columns.Add("Folder Path", lvwFolder.Width - 5)
     
192.         End With
     
193.     End Sub
     
194. 
     
195.     '// ---------------------- ดับเบิลคลิกที่รายการ ListView เพื่อแก้ไขตำแหน่งเปิดโฟลเดอร์ ----------------------
     
196.     Private Sub lvwFolder_DoubleClick(sender As Object, e As EventArgs) Handles lvwFolder.DoubleClick
     
197.         '// เรียกไปยังเหตุการณ์คลิ๊กที่ปุ่ม ToolStrip
     
198.         tsbEditFolder.PerformClick()
     
199.     End Sub
     
200. 
     
201.     Private Sub frmOpenMultipleFolder_FormClosed(sender As Object, e As System.Windows.Forms.FormClosedEventArgs) Handles Me.FormClosed
     
202.         Me.Dispose()
     
203.         GC.SuppressFinalize(Me)
     
204.         Application.Exit()
     
205.     End Sub
     
206. 
     
207. #Region "TOOLBAR EVENTS"
     
208.     '// ทุกๆครั้งที่มีการเปลี่ยนแปลงแก้ไขรายการใน ListView จะทำการบันทึกลง Config.ini ทุกครั้ง (SaveConfig)
     
209.     '// การเพิ่ม Folder Full Path
     
210.     Private Sub tsbAddFolder_Click(sender As Object, e As EventArgs) Handles tsbAddFolder.Click
     
211.         Using fbd As New FolderBrowserDialog
     
212.             fbd.Description = "เลือกโฟลเดอร์ที่ต้องการ"
     
213.             If fbd.ShowDialog() = DialogResult.OK Then
     
214.                 AddFolderToListView(fbd.SelectedPath)
     
215.                 Call SaveConfig()
     
216.             End If
     
217.         End Using
     
218.     End Sub
     
219. 
     
220.     '// แก้ไขตำแหน่ง Folder Full Path
     
221.     Private Sub tsbEditFolder_Click(sender As Object, e As EventArgs) Handles tsbEditFolder.Click
     
222.         If lvwFolder.SelectedItems.Count = 0 Then
     
223.             MessageBox.Show("กรุณาเลือกรายการที่จะแก้ไข", "แก้ไขข้อมูล", MessageBoxButtons.OK, MessageBoxIcon.Information)
     
224.             Exit Sub
     
225.         End If
     
226.         Using fbd As New FolderBrowserDialog
     
227.             fbd.Description = "เลือกโฟลเดอร์ที่ต้องการ"
     
228.             fbd.SelectedPath = lvwFolder.SelectedItems(0).Text   '// ตั้งค่าเริ่มต้นเป็นโฟลเดอร์เดิม
     
229.             If fbd.ShowDialog() = DialogResult.OK Then
     
230.                 lvwFolder.SelectedItems(0).Text = fbd.SelectedPath
     
231.                 Call SaveConfig()
     
232.             End If
     
233.         End Using
     
234.     End Sub
     
235. 
     
236.     '// ลบตำแหน่ง Folder Full Path
     
237.     Private Sub tsbRemoveFolder_Click(sender As Object, e As EventArgs) Handles tsbRemoveFolder.Click
     
238.         If lvwFolder.SelectedItems.Count = 0 Then
     
239.             MessageBox.Show("กรุณาเลือกรายการที่จะลบ", "ลบข้อมูล", MessageBoxButtons.OK, MessageBoxIcon.Information)
     
240.             Exit Sub
     
241.         End If
     
242.         If MessageBox.Show("คุณต้องการลบโฟลเดอร์ที่เลือกใช่หรือไม่?", "ยืนยันการลบ", MessageBoxButtons.YesNo, MessageBoxIcon.Question) = DialogResult.Yes Then
     
243.             lvwFolder.Items.Remove(lvwFolder.SelectedItems(0))
     
244.             Call SaveConfig()
     
245.         End If
     
246.     End Sub
     
247. 
     
248.     '// เปิดโฟลเดอร์ขึ้นมาตามรายการแถวใน ListView
     
249.     Private Sub tsbOpenFolder_Click(sender As Object, e As EventArgs) Handles tsbOpenFolder.Click
     
250.         If lvwFolder.Items.Count = 0 Then
     
251.             MessageBox.Show("ไม่มีรายการโฟลเดอร์ให้เปิด", "รายงานสถานะ", MessageBoxButtons.OK, MessageBoxIcon.Warning)
     
252.             Exit Sub
     
253.         End If
     
254.         For Each itm As ListViewItem In lvwFolder.Items
     
255.             If Directory.Exists(itm.Text) Then Process.Start("explorer.exe", itm.Text)
     
256.         Next
     
257.     End Sub
     
258. 
     
259.     Private Sub tsbExit_Click(sender As Object, e As EventArgs) Handles tsbExit.Click
     
260.         Me.Close()
     
261.     End Sub
     
262. #End Region
     
263. 
     
264. #Region "CONFIG"
     
265.     '// ------------------------------------ โหลดจาก Config.ini ------------------------------------
     
266.     Private Sub LoadConfig()
     
267.         lvwFolder.Items.Clear()
     
268.         imgList.Images.Clear()
     
269.         Dim idx As Integer = 1
     
270.         Do
     
271.             Dim folder As String = ReadIni("Folder", "Path" & idx, vbNullString, iniPath).Replace("""", "")
     
272.             If String.IsNullOrEmpty(folder) OrElse folder = "" Then Exit Do
     
273.             AddFolderToListView(folder)
     
274.             idx += 1
     
275.         Loop
     
276.     End Sub
     
277. 
     
278.     '// ------------------------------------ บันทึกลง Config.ini ------------------------------------
     
279.     Private Sub SaveConfig()
     
280.         '// ล้างค่าทั้ง Section [Folder] ของเดิมทิ้งออกไปก่อน
     
281.         WriteIni("Folder", Nothing, Nothing, iniPath)
     
282.         Dim idx As Integer = 1
     
283.         For Each item As ListViewItem In lvwFolder.Items
     
284.             WriteIni("Folder", "Path" & idx, item.Text, iniPath)
     
285.             idx += 1
     
286.         Next
     
287.     End Sub
     
288. #End Region
     
289. 
     
290. #Region "HELPER"
     
291. 
     
292.     '// เพิ่มรายการ Folder Full Path เข้าไปใน ListView
     
293.     Private Sub AddFolderToListView(folderPath As String)
     
294.         Dim key As String = AddIconToImageList(folderPath)
     
295.         Dim item As New ListViewItem(folderPath, key)
     
296.         lvwFolder.Items.Add(item)
     
297.     End Sub
     
298. 
     
299.     '// ใส่ไอคอนโฟลเดอร์ไว้ก่อนตำแหน่ง Path
     
300.     Private Function AddIconToImageList(folderPath As String) As String
     
301.         Dim key As String = folderPath.ToLower()
     
302.         If Not imgList.Images.ContainsKey(key) Then
     
303.             Try
     
304.                 Dim ico As Icon = GetFolderIcon(folderPath)
     
305.                 imgList.Images.Add(key, ico)
     
306.             Catch ex As Exception
     
307.                 '// ถ้า error ให้ใส่ icon ว่าง
     
308.                 imgList.Images.Add(key, SystemIcons.WinLogo)
     
309.             End Try
     
310.         End If
     
311.         Return key
     
312.     End Function
     
313. #End Region
     
314. 
     
315. #Region "LISTVIEW"
     
316.     '// เมื่อคลิ๊กส่วนหัว (Column) ของ ListView จะทำการจัดเรียงข้อมูลไอเทม ListView
     
317.     Private Sub lvwFolder_ColumnClick(sender As Object, e As ColumnClickEventArgs) Handles lvwFolder.ColumnClick
     
318.         '// ถ้ากดซ้ำที่คอลัมน์เดิมสลับ ASC/DESC การจัดเรียงจากน้อยไปมาก หรือ มากไปน้อย
     
319.         If e.Column = SortColumn Then
     
320.             If SortOrder = SortOrder.Ascending Then
     
321.                 SortOrder = SortOrder.Descending
     
322.             Else
     
323.                 SortOrder = SortOrder.Ascending
     
324.             End If
     
325.         Else
     
326.             SortColumn = e.Column
     
327.             SortOrder = SortOrder.Ascending
     
328.         End If
     
329.         '// เรียกไปยังคลาส ListViewItemComparer
     
330.         lvwFolder.ListViewItemSorter = New ListViewItemComparer(e.Column, SortOrder)
     
331.         lvwFolder.Sort()
     
332.         '// บันทึกข้อมูลลง INI
     
333.         Call SaveConfig()
     
334.     End Sub
     
335. 
     
336.     '// --------------------------------------------------------------------------------------
     
337.     '// TIPS: การปรับฟอนต์ในส่วนของ Column Header ของ ListView Control
     
338.     '// วาด Column Header
     
339.     '// --------------------------------------------------------------------------------------
     
340.     Private Sub lvwFolder_DrawColumnHeader(sender As Object, e As DrawListViewColumnHeaderEventArgs) Handles lvwFolder.DrawColumnHeader
     
341.         Using HeaderFont As New Font("Tahoma", 10, FontStyle.Bold)
     
342.             e.Graphics.FillRectangle(SystemBrushes.ControlDark, e.Bounds)
     
343.             TextRenderer.DrawText(e.Graphics, e.Header.Text, HeaderFont, e.Bounds, Color.White, TextFormatFlags.VerticalCenter Or TextFormatFlags.VerticalCenter)
     
344.         End Using
     
345.     End Sub
     
346. 
     
347.     '// วาด Item
     
348.     Private Sub lvwFolder_DrawItem(sender As Object, e As DrawListViewItemEventArgs) Handles lvwFolder.DrawItem
     
349.         e.DrawDefault = True
     
350.     End Sub
     
351. 
     
352.     '// วาด SubItem
     
353.     Private Sub lvwFolder_DrawSubItem(sender As Object, e As DrawListViewSubItemEventArgs) Handles lvwFolder.DrawSubItem
     
354.         e.DrawDefault = True
     
355.     End Sub
     
356. 
     
357. #End Region
     
358. 
     
359. #Region "FUNCTION"
     
360.     Function MyPath(ByVal AppPath As String) As String
     
361.         Dim p = AppPath.ToLower().Replace("\bin\debug", "").Replace("\bin\release", "").Replace("\bin\x86\debug", "").Replace("\bin\x86\release", "")
     
362.         '// Chr(92) คือ ASCII Code ของเครื่องหมาย Back Slash
     
363.         If Not p.EndsWith(Chr(92)) Then p &= Chr(92)
     
364.         Return p
     
365.     End Function
     
366. #End Region
     
367. 
     
368. End Class

คัดลอกไปที่คลิปบอร์ด

โค้ดโมดูลในการจัดเรียงตัวอักษรของ ListView Control ... (ListViewItemComparer.vb)

1. '// คลาสสำหรับจัดเรียงข้อมูลจากการคลิ๊กเมาส์ที่ส่วนหัวหรือหลักของ ListView
   
2. Public Class ListViewItemComparer
   
3.     Implements IComparer
   
4. 
   
5.     Private col As Integer
   
6.     Private order As SortOrder
   
7. 
   
8.     Public Sub New(column As Integer, sortOrder As SortOrder)
   
9.         col = column
   
10.         order = sortOrder
    
11.     End Sub
    
12. 
    
13.     Public Function Compare(x As Object, y As Object) As Integer Implements IComparer.Compare
    
14.         Dim lviX As ListViewItem = CType(x, ListViewItem)
    
15.         Dim lviY As ListViewItem = CType(y, ListViewItem)
    
16.         Dim result As Integer = String.Compare(lviX.SubItems(col).Text, lviY.SubItems(col).Text)
    
17.         If order = SortOrder.Descending Then result = -result
    
18.         Return result
    
19.     End Function
    
20. End Class

คัดลอกไปที่คลิปบอร์ด

ดาวน์โหลดโค้ดฉบับเต็ม VB.NET (2010) + .Net Framework 4.0 ...