[VB.NET] โค้ดการใช้งาน Line Messaging API เพื่อส่งข้อความและรูปภาพไปยังไลน์กลุ่ม

thongkorn

*** จะต้องติดตั้ง CloudinaryDotNet เพื่อใช้ในการอัพโหลดรูปภาพเข้าไปใหม่ก่อนด้วย เพราะโค้ดต้นฉบับไม่ได้แนบไฟล์ DLL ไปด้วย ***
*** การติดตั้ง CloudinaryDotNet จะติดตั้ง NewTonSoft มาให้อัตโนมัติ ***

การใช้ Nuget เพื่อทำการติดตั้ง CloudinaryDotNet ... (เป็นที่เก็บไฟล์ Media ต่างๆ) ...ไปที่เมนู Tools --> Nuget Package Manager --> Manage Nuget Packages for solution ...

คลิปวิดีโอในการรับค่า Webhook สำหรับ Line Messaging API ...

โค้ดการใช้งาน Line Messaging API เพื่อส่งข้อความและรูปภาพไปยังไลน์กลุ่ม โดยการใช้โค้ดเดิมจาก โค้ดการใช้ Line Messaging API ด้วยการส่งไฟล์รูปภาพไปเก็บไว้ที่ Cloudinary ก่อนส่งต่อไปที่ LINE ซึ่งไม่ได้มีการเปลี่ยนแปลงแก้ไขใดๆ ยกเว้นเพิ่มเติมในเรื่องของการประกาศตัวแปร GROUP_ID เข้ามาใช้งานแทนที่ USER_ID ...

สมัครใช้งาน Cloudinary.com ได้ที่นี่

คลิปวิดีโอในการสมัครใช้งาน Line Official Account เพื่อรับค่า Channel Access Token และ UserID

คลิปวิดีโอในการสมัครเข้าใช้งานและดูรายละเอียดของ Cloudinary ...

สคริปท์สำหรับการรับค่า Webhook จาก Google App Script ...

1. function sendLineNotifyToGroup() {
   
2.   var accessToken = 'YOUR_CHANNEL_ACCESS_TOKEN'; // ใส่ Access Token ของคุณ
   
3.   var groupId = 'YOUR_GROUP_ID'; // ใส่ Group ID ที่ได้จาก webhook หรือ debug log
   
4. 
   
5.   var message = 'แจ้งเตือน: มีรายการใหม่เข้ามาในระบบ';
   
6. 
   
7.   var payload = {
   
8.     to: groupId,
   
9.     messages: [
   
10.       {
    
11.         type: 'text',
    
12.         text: message
    
13.       }
    
14.     ]
    
15.   };
    
16. 
    
17.   var options = {
    
18.     method: 'post',
    
19.     contentType: 'application/json',
    
20.     headers: {
    
21.       'Authorization': 'Bearer ' + accessToken
    
22.     },
    
23.     payload: JSON.stringify(payload)
    
24.   };
    
25. 
    
26.   var url = 'https://api.line.me/v2/bot/message/push';
    
27.   var response = UrlFetchApp.fetch(url, options);
    
28. 
    
29.   Logger.log(response.getContentText()); // แสดงผลลัพธ์
    
30. }

คัดลอกไปที่คลิปบอร์ด

มาดูโค้ดฉบับเต็มกันเถอะ ... อย่าลืมใส่ค่าคงที่ต่างๆก่อนที่จะรันโปรแกรมด้วย ...

1. '// สมัครการใช้งาน Line Messaging API ที่
   
2. '// https://manager.line.biz/
   
3. '// https://developers.line.biz/en/
   
4. '// จากนั้น สร้าง Channel ใน Line Messaging API
   
5. '// รับ Channel Access Token และ User ID จากหน้า Line Console
   
6. 
   
7. '// ติดตั้ง Library Newtonsoft.Json เพื่อช่วยจัดการ JSON
   
8. '// ใน NuGet Package Manager Console ใช้คำสั่ง:
   
9. '// Install-Package Newtonsoft.Json
   
10. '// .Net Framework 4.5
    
11. 
    
12. '// .Net SDK & Cloudinary Document
    
13. '// https://cloudinary.com/documentation/dotnet_integration
    
14. '// Sign Up
    
15. '// https://www.cloudinary.com
    
16. 
    
17. Imports System.IO
    
18. Imports CloudinaryDotNet
    
19. Imports CloudinaryDotNet.Actions
    
20. Imports System.Net.Http
    
21. Imports System.Net.Http.Headers
    
22. Imports Newtonsoft.Json
    
23. Imports System.Text
    
24. 
    
25. Public Class frmLineMessengerGroup
    
26.     '// ------------------------------------------------------------------------------------------------
    
27.     '// เก็บตำแหน่งและชื่อไฟล์ภาพต้นฉบับที่ต้องการอัพโหลด
    
28.     Dim PictureUploadPath As String = String.Empty
    
29.     '// แยกชื่อไฟล์+นามสกุล ออกจากโฟลเดอร์
    
30.     Dim UploadFileName As String = ""
    
31.     '// Default path.
    
32.     Dim PictureDefaultPath As String = MyPath(Application.StartupPath) & "Images"
    
33. 
    
34.     '// Cloudinary Configuration
    
35.     Private Const CLOUD_NAME As String = "CLOUD_NAME"
    
36.     Private Const API_KEY As String = "API_KEY"
    
37.     Private Const API_SECRET As String = "API_SECRET"
    
38.     '// กำหนดโฟลเดอร์ที่เก็บไฟล์บน Cloudinary
    
39.     Private Const CLOUD_FOLDER As String = "LineAPI"    '// ตั้งชื่อโฟลเดอร์เอาเอง หากใน Cloudinary ไม่มี มันจะสร้างให้อัตโนมัติ
    
40. 
    
41.     '// Line Bot Config
    
42.     Private Const LINE_ACCESS_TOKEN As String = "LINE_ACCESS_TOKEN"
    
43.     Private Const USER_ID As String = "USER_ID" '// งานนี้ไม่ได้ใช้
    
44. 
    
45.     Private Const GROUP_ID As String = "GROUP_ID"
    
46.     '// ------------------------------------------------------------------------------------------------
    
47. 
    
48.     Private Sub frmLineMessengerGroup_Load(sender As Object, e As EventArgs) Handles MyBase.Load
    
49.         txtMessage.Text = "ทดสอบการส่งข้อความและรูปภาพในไลน์กลุ่ม ด้วยการใช้งาน Line Messaging API"
    
50.     End Sub
    
51. 
    
52.     '// ------------------------------------------------------------------------------------------------
    
53.     '// ส่งข้อความและรูปภาพไปยัง LINE
    
54.     '// ------------------------------------------------------------------------------------------------
    
55.     Private Sub btnSendMessage_Click(sender As Object, e As EventArgs) Handles btnSendMessage.Click
    
56.         '// ตรวจสอบว่าทั้งข้อความและภาพว่างหรือไม่
    
57.         If String.IsNullOrWhiteSpace(txtMessage.Text.Trim) AndAlso String.IsNullOrWhiteSpace(PictureUploadPath) Then
    
58.             MessageBox.Show("กรุณาใส่ข้อความหรือเลือกภาพก่อนส่ง", "คำเตือน", MessageBoxButtons.OK, MessageBoxIcon.Warning)
    
59.             Return
    
60.         Else
    
61.             '// ทำการส่งข้อความและไฟล์ภาพไปใน Line Bot
    
62.             Call UploadImageAndSendToLine(PictureUploadPath, txtMessage.Text & vbCrLf & "วันที่ - เวลา: " & Now())
    
63.         End If
    
64.         '// Clear
    
65.         UploadFileName = ""
    
66.         PictureUploadPath = String.Empty
    
67.         picData.Image = Image.FromFile(PictureDefaultPath & "NoImage.gif")
    
68.     End Sub
    
69. 
    
70.     '// ------------------------------------------------------------------------------------------------
    
71.     '// คำสั่ง Async ใช้เพื่อระบุว่าฟังก์ชันหรือเมธอดสามารถดำเนินการแบบ Asynchronous
    
72.     '// หรือเป็นทำงานแบบไม่รอให้เสร็จสมบูรณ์ก่อนที่จะไปทำคำสั่งถัดไปได้
    
73.     '// โดยปกติจะใช้ร่วมกับคำสั่ง Await เพื่อเรียกใช้งานที่ใช้เวลานาน
    
74.     '// เช่น การร้องขอข้อมูลจาก API, อ่าน/เขียนไฟล์, หรือรอเครือข่าย โดยไม่บล็อกส่วนที่เหลือของแอพพลิเคชัน
    
75.     '// ------------------------------------------------------------------------------------------------
    
76.     Public Async Function UploadImageAndSendToLine(ByVal imagePath As String, ByVal message As String) As Task
    
77.         Dim account = New Account(CLOUD_NAME, API_KEY, API_SECRET)
    
78.         Dim cloudinary = New Cloudinary(account)
    
79.         Dim uploadResult As ImageUploadResult = Nothing
    
80.         Dim publicId As String = Nothing
    
81.         Dim imageUrl As String = String.Empty
    
82.         Dim url As String = "https://api.line.me/v2/bot/message/push"
    
83.         Try
    
84.             '// 1. Upload Image to Cloudinary
    
85.             If Not String.IsNullOrEmpty(imagePath) AndAlso IO.File.Exists(imagePath) Then
    
86.                 Dim uploadParams = New ImageUploadParams() With {
    
87.                     .File = New FileDescription(imagePath),
    
88.                     .Folder = CLOUD_FOLDER '// Line API folder on Cloudinary.
    
89.                 }
    
90.                 uploadResult = cloudinary.Upload(uploadParams)
    
91.                 imageUrl = uploadResult.SecureUrl.ToString()
    
92.                 publicId = uploadResult.PublicId
    
93.             End If
    
94. 
    
95.             '// 2. Send to LINE Messaging API
    
96.             Using client As New HttpClient()
    
97.                 client.DefaultRequestHeaders.Authorization = New AuthenticationHeaderValue("Bearer", LINE_ACCESS_TOKEN)
    
98.                 '// เตรียมรายการข้อความ สร้าง Payload ตามรูปแบบที่ Line API ต้องการ
    
99.                 '// Payload คือเนื้อหาข้อมูลที่ส่งไปยัง Line Server ผ่าน API เช่น การส่งข้อความ, การส่งรูปภาพ หรือการสร้าง Flex Message
    
100.                 '// ประกาศตัวแปร messages เป็นแบบ List(Of Object) จากนั้นค่อยนำไปแปลงให้อยู่ในรูปแบบ JSON Format
     
101.                 Dim messages = New List(Of Object)
     
102.                 '// ตรวจสอบว่ามีข้อความ
     
103.                 If Not String.IsNullOrEmpty(message) Then
     
104.                     messages.Add(New With {.type = "text", .text = message})
     
105.                 End If
     
106.                 '// ตรวจสอบว่ามี URL รูปภาพ
     
107.                 If Not String.IsNullOrEmpty(imageUrl) Then
     
108.                     messages.Add(New With {
     
109.                         .type = "image",
     
110.                         .originalContentUrl = imageUrl,
     
111.                         .previewImageUrl = imageUrl
     
112.                     })
     
113.                 End If
     
114.                 Dim payload = New With {
     
115.                     .to = GROUP_ID,
     
116.                     .messages = messages.ToArray()
     
117.                 }
     
118.                 '// แปลงเป็น JSON แล้วส่ง
     
119.                 Dim json = JsonConvert.SerializeObject(payload, Formatting.Indented)
     
120.                 '// ตัวอย่าง:
     
121.                 '// {
     
122.                 '//  "to": "USER_ID",
     
123.                 '//  "messages": [
     
124.                 '//     {
     
125.                 '//       "type": "text",
     
126.                 '//       "text": "สวัสดีครับ! นี่คือข้อความจาก Line Messaging API"
     
127.                 '//     },
     
128.                 '//     {
     
129.                 '//       "type": "image",
     
130.                 '//       "originalContentUrl": "https://example.com/image.jpg",
     
131.                 '//       "previewImageUrl": "https://example.com/image_preview.jpg" (หรือใช้ชื่อไฟล์ภาพ Content ตัวเดียวกันได้เลย)
     
132.                 '//     }
     
133.                 '//   ]
     
134.                 '// }
     
135.                 Dim content = New StringContent(json, Encoding.UTF8, "application/json")
     
136.                 Dim response = Await client.PostAsync(url, content)
     
137.                 Dim result = Await response.Content.ReadAsStringAsync()
     
138.                 If Not response.IsSuccessStatusCode Then
     
139.                     MessageBox.Show("เกิดข้อผิดพลาด: " & response.StatusCode & vbCrLf & result, "Report Error", MessageBoxButtons.OK, MessageBoxIcon.Error)
     
140.                 End If
     
141.             End Using
     
142.         Catch ex As Exception
     
143.             MessageBox.Show("Error: " & ex.Message)
     
144. 
     
145.             '// 3: Delete Image From Cloudinary.
     
146.         Finally
     
147.             If Not String.IsNullOrEmpty(publicId) Then
     
148.                 Try
     
149.                     Dim deletionParams As New DeletionParams(publicId)
     
150.                     Dim deletionResult = cloudinary.Destroy(deletionParams)
     
151.                 Catch ex1 As Exception
     
152.                     MessageBox.Show("ลบภาพไม่สำเร็จ: " & ex1.Message, "Report Error", MessageBoxButtons.OK, MessageBoxIcon.Error)
     
153.                 End Try
     
154.             End If
     
155.         End Try
     
156.     End Function
     
157. 
     
158.     '// ------------------------------------------------------------------------------------------------
     
159.     '// เบราซ์หาไฟล์ภาพ
     
160.     '// ------------------------------------------------------------------------------------------------
     
161.     Private Sub btnBrowse_Click(sender As Object, e As EventArgs) Handles btnBrowse.Click
     
162.         Dim dlgImage As OpenFileDialog = New OpenFileDialog()
     
163.         '// Open File Dialog
     
164.         With dlgImage
     
165.             .InitialDirectory = PictureDefaultPath
     
166.             .Title = "Select Image File"
     
167.             .Filter = "Format (*.jpg;*.jpeg;*.png)|*.jpg;*.jpeg;*.png"
     
168.             .FilterIndex = 1
     
169.             .RestoreDirectory = True
     
170.         End With
     
171.         '// Select OK after Browse ...
     
172.         If dlgImage.ShowDialog() = DialogResult.OK Then
     
173.             '// ตรวจสอบก่อนว่าขนาดไฟล์เกิน 1 MB. หรือไม่ (Cloudinary น่าจะอัพโหลดได้สูงสุด 10 MB.)
     
174.             Dim info As New FileInfo(dlgImage.FileName)
     
175.             If (info.Length / 1024) > 1024 Then
     
176.                 MessageBox.Show("The image file you selected is of size " & Format((info.Length / 1024), "#,##0") & " KB. is too big more than 1,024 KB.", "Report Status", MessageBoxButtons.OK, MessageBoxIcon.Warning)
     
177.                 Exit Sub
     
178.             End If
     
179.             '// Put the current image file into PictureBox Control.
     
180.             picData.Image = Image.FromFile(dlgImage.FileName)
     
181.             '// เอาเฉพาะชื่อไฟล์และนามสกุลภาพ (Filename + Extension) เช่น thongkorn.png
     
182.             UploadFileName = dlgImage.SafeFileName
     
183.             '// เอาไฟล์ภาพมาเต็มพาธ เพื่อระบุต้นทางไฟล์ก่อนทำการอัพโหลด
     
184.             PictureUploadPath = dlgImage.FileName
     
185.         End If
     
186.     End Sub
     
187. 
     
188.     '// ------------------------------------------------------------------------------------------------
     
189.     Private Sub btnClear_Click(sender As Object, e As EventArgs) Handles btnClear.Click
     
190.         picData.Image = Image.FromFile(PictureDefaultPath & "NoImage.gif")
     
191.         UploadFileName = ""
     
192.         PictureUploadPath = String.Empty
     
193.     End Sub
     
194. 
     
195.     Private Sub btnExit_Click(sender As Object, e As EventArgs) Handles btnExit.Click
     
196.         Me.Close()
     
197.     End Sub
     
198. 
     
199.     Private Sub frmLineMessengerGroup_FormClosed(sender As Object, e As FormClosedEventArgs) Handles Me.FormClosed
     
200.         Me.Dispose()
     
201.         GC.SuppressFinalize(Me)
     
202.         Application.Exit()
     
203.     End Sub
     
204. 
     
205. 
     
206. #Region "FUNCTION"
     
207.     '// / --------------------------------------------------------------------------------
     
208.     '// / Get my project path
     
209.     '// / AppPath = C:\My Project\bin\debug
     
210.     '// / Replace "\bin\debug" with ""
     
211.     '// / Return : C:\My Project\
     
212.     Function MyPath(ByVal AppPath As String) As String
     
213.         '/ MessageBox.Show(AppPath);
     
214.         AppPath = AppPath.ToLower()
     
215.         '/ Return Value
     
216.         MyPath = AppPath.Replace("\bin\debug", "").Replace("\bin\release", "").Replace("\bin\x86\debug", "")
     
217.         '// If not found folder then put the \ (BackSlash) at the end.
     
218.         If Microsoft.VisualBasic.Right(MyPath, 1) <> Chr(92) Then MyPath = MyPath & Chr(92)
     
219.     End Function
     
220. 
     
221. #End Region
     
222. End Class

คัดลอกไปที่คลิปบอร์ด

ดาวน์โหลดโค้ดต้นฉบับ VB.NET (.Net Framework 4.5.2+) ... ได้ที่นี่ ...