[VB.NET] โค้ดการใช้ Line Messaging API ด้วยการส่งข้อความและรูปภาพ ด้วยการใช้ FTP

thongkorn

Add Refrences ...
- NewtonSoft.Json (จัดข้อความให้อยู่ให้อยู่ในรูปแบบ JSON)

- WinSCPnet.dll (FTP - File Transfer Protocol ในการอัพโหลดและดาวน์โหลดไฟล์ภาพ ระหว่างคอมพิวเตอร์ และ Hosting)
*** ทั้ง 2 ไฟล์นี้เป็นของฟรีครับ ***

วิธีการส่งภาพผ่าน LINE Messaging API ด้วย VB.NET: คุณจะต้องดำเนินการตามขั้นตอนเหล่านี้แทน

(1) คุณต้องมี Server ที่สามารถเข้าถึงได้จากอินเทอร์เน็ต (เช่น Web Server, Cloud Storage อย่าง AWS S3, Google Cloud Storage, หรือบริการฝากไฟล์อื่นๆ)
เขียนโค้ด VB.NET เพื่ออัปโหลดไฟล์ภาพจาก Local Computer ของคุณไปยัง Server นั้น เมื่ออัปโหลดสำเร็จ คุณจะได้รับ URL ของรูปภาพที่อยู่บน Server

(2) สร้าง Payload สำหรับส่งภาพ:
สร้าง JSON Payload ตามรูปแบบที่ LINE Messaging API กำหนดสำหรับการส่งข้อความประเภทรูปภาพ ใน Payload จะต้องมี type เป็น "image"
และมี Properties ดังนี้:
- originalContentUrl: URL ของรูปภาพต้นฉบับ (ขนาดเต็ม) ที่อยู่บน Server ของคุณ
- previewImageUrl: URL ของรูปภาพขนาดเล็กสำหรับแสดงเป็นภาพตัวอย่าง (สามารถใช้ URL เดียวกับ originalContentUrl ได้หากไม่ต้องการภาพตัวอย่างแยก)

(3) ส่ง HTTP POST Request ไปยัง LINE API:
ใช้ HttpClient ใน VB.NET เพื่อส่ง HTTP POST Request ไปยัง Endpoint ของ LINE Messaging API สำหรับการส่งข้อความ (เช่น https://api.line.me/v2/bot/message/push หรือ https://api.line.me/v2/bot/message/reply) กำหนด Headers ให้ถูกต้อง โดยเฉพาะ Authorization (Bearer token) และ Content-Type (application/json)

(4) ใส่ JSON Payload ที่สร้างไว้ใน Body ของ Request

(04-05-2568) แอดมินใช้บริการ Hosting ของฟรีจาก www.serv00.com แต่ปัจจุบันนี้ผู้ให้บริการได้ปิดการรับสมัคร Account เข้าใช้งานอยู่ จะต้องไปหา Hosting ที่ใหม่ด้วยล่ะครับ

สมัครการใช้งาน Line Official Account ที่
https://manager.line.biz/
https://developers.line.biz/en/

คลิปวิดีโอในการสมัครใช้งาน Line Official Account เพื่อรับค่า Channel Access Token และ UserID

มาดูโค้ดฉบับเต็มกันเถอะ ... (ฟอร์มหลัก)

1. '// สมัครการใช้งาน Line Messaging API ที่
   
2. '// https://manager.line.biz/
   
3. '// https://developers.line.biz/en/
   
4. '// จากนั้น สร้าง Channel ใน Line Messaging API
   
5. '// รับ Channel Access Token และ User ID จากหน้า Line Console
   
6. 
   
7. '// ติดตั้ง Library Newtonsoft.Json เพื่อช่วยจัดการ JSON
   
8. '// ใน NuGet Package Manager Console ใช้คำสั่ง:
   
9. '// Install-Package Newtonsoft.Json
   
10. '// .Net Framework 4.5
    
11. 
    
12. Imports System.IO
    
13. Imports WinSCP
    
14. 
    
15. Public Class frmLineApiMsgImg
    
16.     '// ------------------------------------------------------------------------------------------------
    
17. '// เก็บตำแหน่งและชื่อไฟล์ภาพต้นฉบับที่ต้องการอัพโหลด
    
18.     Dim PictureUploadPath As String = String.Empty
    
19.     '// แยกชื่อไฟล์+นามสกุล ออกจากโฟลเดอร์
    
20.     Dim UploadFileName As String = ""
    
21.     '// Default path.
    
22.     Dim PictureDefaultPath As String = MyPath(Application.StartupPath) & "Images"
    
23. 
    
24.     '// ตำแหน่งของไฟล์ภาพบน Hosting เพื่อนำมาแสดงผล (โฟลเดอร์ uploadimages อยู่ภายใต้ public_html)
    
25.     '// ต้องเปลี่ยน Sub Domain จาก g2gnet ให้เป็นไปตามที่สมัครเอาไว้ด้วยล่ะครับ
    
26.     Dim MyURL As String = "https://g2gnet.serv00.net/uploadimages/"
    
27.     '// ตำแหน่งในการอัพโหลดไฟล์ภาพ (FTP)
    
28.     Dim RemoteDir As String = "domains/g2gnet.serv00.net/public_html/uploadimages/"
    
29.     '// For Login to Hosting.
    
30.     Dim HostName As String = "HOST_NAME"
    
31.     Dim UName As String = "USER_NAME"
    
32.     Dim Pwd As String = "PASSWORD"
    
33. 
    
34.     Private Sub frmLineApiMsgImg_Load(sender As Object, e As EventArgs) Handles MyBase.Load
    
35.         txtMessage.Text = "ทดสอบการทำงานของ Line Messaging API ด้วยการส่งข้อความและรูปภาพ"
    
36.     End Sub
    
37. 
    
38.     '// ------------------------------------------------------------------------------------------------
    
39.     '// คำสั่ง Async ใช้เพื่อระบุว่าฟังก์ชันหรือเมธอดสามารถดำเนินการแบบ Asynchronous
    
40.     '// หรือเป็นทำงานแบบไม่รอให้เสร็จสมบูรณ์ก่อนที่จะไปทำคำสั่งถัดไปได้
    
41.     '// โดยปกติจะใช้ร่วมกับคำสั่ง Await เพื่อเรียกใช้งานที่ใช้เวลานาน
    
42.     '// เช่น การร้องขอข้อมูลจาก API, อ่าน/เขียนไฟล์, หรือรอเครือข่าย โดยไม่บล็อกส่วนที่เหลือของแอพพลิเคชัน
    
43.     '// ------------------------------------------------------------------------------------------------
    
44.     Private Async Sub btnSendMessage_Click(sender As Object, e As EventArgs) Handles btnSendMessage.Click
    
45.         '// หากไม่มีข้อความก็ไม่ต้องส่ง
    
46.         'If (String.IsNullOrEmpty(txtMessage.Text.Trim)) Then Return
    
47. 
    
48.         '// ตำแหน่งการแสดงผลไฟล์ภาพ
    
49.         Dim imageURL As String = String.Empty
    
50.         '// "https://g2gnet.serv00.net/uploadimages/" + "ชื่อไฟล์ภาพ+นามสกุล"
    
51.         If Not String.IsNullOrEmpty(UploadFileName) Then imageURL = MyURL + UploadFileName
    
52. 
    
53.         '// หากมีรูปภาพต้องอัพโหลดขึ้น Hosting ก่อน
    
54.         '// RemoteDir = "domains/g2gnet.serv00.net/public_html/uploadimages/" + UploadFileName
    
55.         If Not (String.IsNullOrEmpty(UploadFileName)) Then Call UploadRemoteFile(RemoteDir + UploadFileName)
    
56. 
    
57.         '// เริ่มต้นใช้ Line Bot ด้วยการเรียกไปยังคลาส LineMessagingAPI
    
58.         Dim LineAPI As New LineMessagingAPI()
    
59.         '// Await:
    
60.         '// ใช้เพื่อรอการทำงานของงานที่ใช้เวลานาน โดยไม่บล็อกการทำงานของเธรดหลัก
    
61.         '// คำสั่งหลัง Await จะรันเมื่อการทำงานนั้นเสร็จสมบูรณ์
    
62.         Await LineAPI.SendImageMessageToLineAsync(txtMessage.Text, imageURL)
    
63. 
    
64.         '// หากต้องการลบไฟล์ภาพที่อัพโหลดออกไปหลังจากที่ส่งไปใน Line เรียบร้อย
    
65.         If Not String.IsNullOrEmpty(imageURL) Then Call DeleteRemoteFile(RemoteDir + UploadFileName)
    
66. 
    
67.         '// Clear
    
68.         UploadFileName = ""
    
69.         PictureUploadPath = String.Empty
    
70.         picData.Image = Image.FromFile(PictureDefaultPath & "NoImage.gif")
    
71.     End Sub
    
72. 
    
73.     '// ------------------------------------------------------------------------------------------------
    
74.     '// เบราซ์หาไฟล์ภาพ
    
75.     '// ------------------------------------------------------------------------------------------------
    
76.     Private Sub btnBrowse_Click(sender As Object, e As EventArgs) Handles btnBrowse.Click
    
77.         Dim dlgImage As OpenFileDialog = New OpenFileDialog()
    
78.         '// Open File Dialog
    
79.         With dlgImage
    
80.             .InitialDirectory = PictureDefaultPath
    
81.             .Title = "Select Image File"
    
82.             .Filter = "Format (*.jpg;*.jpeg;*.png)|*.jpg;*.jpeg;*.png"
    
83.             .FilterIndex = 1
    
84.             .RestoreDirectory = True
    
85.         End With
    
86.         '// Select OK after Browse ...
    
87.         If dlgImage.ShowDialog() = DialogResult.OK Then
    
88.             '// Check file size don't over 1 MB.
    
89.             Dim info As New FileInfo(dlgImage.FileName)
    
90.             If (info.Length / 1024) > 1024 Then
    
91.                 MessageBox.Show("The image file you selected is of size " & Format((info.Length / 1024), "#,##0") & " KB. is too big more than 1,024 KB.", "Report Status", MessageBoxButtons.OK, MessageBoxIcon.Warning)
    
92.                 Exit Sub
    
93.             End If
    
94.             '// Put the current image file into PictureBox Control.
    
95.             picData.Image = Image.FromFile(dlgImage.FileName)
    
96.             '// เอาเฉพาะชื่อไฟล์และนามสกุลภาพ (Filename + Extension) เช่น thongkorn.png
    
97.             UploadFileName = dlgImage.SafeFileName
    
98.             '// เอาไฟล์ภาพมาเต็มพาธ เพื่อระบุต้นทางไฟล์ก่อนทำการอัพโหลด
    
99.             PictureUploadPath = dlgImage.FileName
    
100.         End If
     
101.     End Sub
     
102. 
     
103.     '// ------------------------------------------------------------------------------------------------
     
104.     '// UPLOAD FILE to HOSTING.
     
105.     '// ------------------------------------------------------------------------------------------------
     
106.     Private Sub UploadRemoteFile(ByVal imgUrl As String)
     
107.         If String.IsNullOrEmpty(UploadFileName) Then Return
     
108.         '//
     
109.         Me.Cursor = Cursors.WaitCursor
     
110.         Try
     
111.             '// Setup session options
     
112.             Dim sessionOptions As New SessionOptions
     
113.             With sessionOptions
     
114.                 .Protocol = Protocol.Ftp
     
115.                 .HostName = HostName
     
116.                 .UserName = UName
     
117.                 .Password = Pwd
     
118.                 '// FTP ไม่ต้องใช้
     
119.                 '.SshHostKeyFingerprint = "ssh-rsa 2048 XX:XX:XX:XX:XX:XX:XX:XX:XX:XX:XX:XX:XX:XX:XX:XX"
     
120.             End With
     
121.             Using Session As New Session
     
122.                 '// Connect
     
123.                 Session.Open(sessionOptions)
     
124.                 '// Upload files
     
125.                 Dim TransferOptions As New TransferOptions
     
126.                 TransferOptions.TransferMode = TransferMode.Binary
     
127. 
     
128.                 Dim TransferResult As TransferOperationResult
     
129.                 '// ตำแหน่งไฟล์ต้นฉบับแบบ Full Path และ Remote Directory ปลายทาง
     
130.                 '// RemoteDir = "domains/g2gnet.serv00.net/public_html/uploadimages/"
     
131.                 TransferResult = Session.PutFiles(PictureUploadPath, imgUrl, False, TransferOptions)
     
132.                 '// Throw on any error
     
133.                 TransferResult.Check()
     
134.             End Using
     
135.         Catch ex As Exception
     
136.             MessageBox.Show(ex.Message)
     
137.         Finally
     
138.             Me.Cursor = Cursors.Default
     
139.         End Try
     
140.     End Sub
     
141. 
     
142.     '// ------------------------------------------------------------------------------------------------
     
143.     '// การลบไฟล์แบบ Remote ด้วย WinSCP FTP
     
144.     '// ------------------------------------------------------------------------------------------------
     
145.     Private Sub DeleteRemoteFile(ByVal imgUrl As String)
     
146.         Me.Cursor = Cursors.WaitCursor
     
147.         Try
     
148.             Dim sessionOptions As New SessionOptions With {
     
149.             .Protocol = Protocol.Ftp,
     
150.             .HostName = HostName,
     
151.             .UserName = UName,
     
152.             .Password = Pwd
     
153.         }
     
154.             Using session As New Session
     
155.                 session.Open(sessionOptions)
     
156.                 '// ลบไฟล์บน Remote ที่ "domains/g2gnet.serv00.net/public_html/uploadimages/" + "ชื่อไฟล์ภาพ+นามสกุล"
     
157.                 Dim removalResult As RemovalOperationResult = session.RemoveFiles(imgUrl)
     
158.                 '// ตรวจสอบว่าเกิดข้อผิดพลาดหรือไม่
     
159.                 removalResult.Check()
     
160.                 'MessageBox.Show("ลบไฟล์สำเร็จ!!!", "Complete", MessageBoxButtons.OK, MessageBoxIcon.Information)
     
161.             End Using
     
162.         Catch ex As Exception
     
163.             MessageBox.Show("เกิดข้อผิดพลาด: " & ex.Message, "Report Status", MessageBoxButtons.OK, MessageBoxIcon.Error)
     
164.         Finally
     
165.             Me.Cursor = Cursors.Default
     
166.         End Try
     
167.     End Sub
     
168. 
     
169.     '// ------------------------------------------------------------------------------------------------
     
170.     Private Sub btnClear_Click(sender As Object, e As EventArgs) Handles btnClear.Click
     
171.         picData.Image = Image.FromFile(PictureDefaultPath & "NoImage.gif")
     
172.         UploadFileName = ""
     
173.         PictureUploadPath = String.Empty
     
174.     End Sub
     
175. 
     
176.     Private Sub btnExit_Click(sender As Object, e As EventArgs) Handles btnExit.Click
     
177.         Me.Close()
     
178.     End Sub
     
179. 
     
180.     Private Sub frmLineApiMsgImg_FormClosed(sender As Object, e As FormClosedEventArgs) Handles Me.FormClosed
     
181.         Me.Dispose()
     
182.         GC.SuppressFinalize(Me)
     
183.         Application.Exit()
     
184.     End Sub
     
185. 
     
186. #Region "FUNCTION"
     
187.     ' / --------------------------------------------------------------------------------
     
188.     ' / Get my project path
     
189.     ' / AppPath = C:\My Project\bin\debug
     
190.     ' / Replace "\bin\debug" with ""
     
191.     ' / Return : C:\My Project\
     
192.     Function MyPath(ByVal AppPath As String) As String
     
193.         '/ MessageBox.Show(AppPath);
     
194.         AppPath = AppPath.ToLower()
     
195.         '/ Return Value
     
196.         MyPath = AppPath.Replace("\bin\debug", "").Replace("\bin\release", "").Replace("\bin\x86\debug", "")
     
197.         '// If not found folder then put the \ (BackSlash) at the end.
     
198.         If Microsoft.VisualBasic.Right(MyPath, 1) <> Chr(92) Then MyPath = MyPath & Chr(92)
     
199.     End Function
     
200. #End Region
     
201. 
     
202. End Class

คัดลอกไปที่คลิปบอร์ด

Class ในการส่งข้อความและรูปภาพไปยัง Chat Bot ... (LineMessagingAPI.vb)

1. Imports System.Net.Http
   
2. Imports Newtonsoft.Json
   
3. Imports System.Text
   
4. Imports System.Net.Http.Headers
   
5. 
   
6. Public Class LineMessagingAPI
   
7.     '// Channel Access Token จาก Line Developer Console
   
8.     Public Shared AccessToken As String = "CHANNEL_ACCESS_TOKEN"    '// เปลี่ยนด้วย
   
9.     '// ต้องใส่ User ID ของคุณ
   
10.     Public Const YourUserId As String = "USER_ID"    '// เปลี่ยนด้วย
    
11. 
    
12.     '// --------------------------------------------------------------------------------
    
13.     '// ฟังค์ชั่นในการทดสอบ Bot ตัวเอง
    
14.     '// LINE ไม่รองรับการอัปโหลดไฟล์ภาพ โดยตรงจากเครื่องผู้ใช้ (เช่น C:\image.jpg) ผ่าน API ประเภท push หรือ reply message
    
15.     '// LINE ต้องการภาพผ่าน URL เท่านั้นโดย :
    
16.     '// - originalContentUrl และ previewImageUrl ต้องเป็นลิงก์ HTTPS
    
17.     '// - ต้องสามารถเข้าถึงได้โดยสาธารณะ (Public URL)
    
18.     '// - รองรับไฟล์ .jpg, .png, .jpeg และไม่เกิน 1MB
    
19.     '// --------------------------------------------------------------------------------
    
20.     Public Async Function SendImageMessageToLineAsync(message As String, imageUrl As String) As Task
    
21.         Try
    
22.             Using client As New HttpClient()
    
23.                 client.DefaultRequestHeaders.Accept.Add(New System.Net.Http.Headers.MediaTypeWithQualityHeaderValue("application/json"))
    
24.                 client.DefaultRequestHeaders.Authorization = New AuthenticationHeaderValue("Bearer", AccessToken)
    
25. 
    
26.                 Dim url As String = "https://api.line.me/v2/bot/message/push"
    
27.                 '// เตรียมรายการข้อความ สร้าง Payload ตามรูปแบบที่ Line API ต้องการ
    
28.                 '// Payload คือเนื้อหาข้อมูลที่ส่งไปยัง Line Server ผ่าน API เช่น การส่งข้อความ, การส่งรูปภาพ หรือการสร้าง Flex Message
    
29.                 Dim MessagePayload As New List(Of Object)
    
30.                 '// ตรวจสอบว่ามีข้อความ
    
31.                 If Not String.IsNullOrWhiteSpace(message) Then
    
32.                     MessagePayload.Add(New With {
    
33.                     .type = "text",
    
34.                     .text = message
    
35.                 })
    
36.                 End If
    
37.                 '// ตรวจสอบว่ามี URL รูปภาพ
    
38.                 If Not String.IsNullOrWhiteSpace(imageUrl) Then
    
39.                     MessagePayload.Add(New With {
    
40.                     .type = "image",
    
41.                     .originalContentUrl = imageUrl,
    
42.                     .previewImageUrl = imageUrl
    
43.                 })
    
44.                 End If
    
45.                 '// สำหรับวิดีโอ
    
46.                 'If Not String.IsNullOrEmpty(videoUrl) AndAlso Not String.IsNullOrEmpty(videoPreviewUrl) Then
    
47.                 'MessagePayload.Add(New With {
    
48.                 'Key .type = "video",
    
49.                 'Key .originalContentUrl = videoUrl,
    
50.                 'Key .previewImageUrl = videoPreviewUrl
    
51.                 '})
    
52.                 'End If
    
53.                 '// ถ้าไม่มีอะไรส่งเลย ให้แจ้งเตือนแล้วเด้งออกไปเลย
    
54.                 If MessagePayload.Count = 0 Then
    
55.                     MessageBox.Show("ไม่พบข้อความหรือรูปภาพที่จะส่ง", "No Content", MessageBoxButtons.OK, MessageBoxIcon.Warning)
    
56.                     Return
    
57.                 End If
    
58.                 '// สร้าง Payload ที่จะส่ง
    
59.                 Dim Payload = New With {
    
60.                     .to = YourUserId,
    
61.                     .messages = MessagePayload.ToArray()
    
62.                 }
    
63.                 '// แปลงเป็น JSON แล้วส่ง
    
64.                 Dim JsonPayload As String = JsonConvert.SerializeObject(Payload, Formatting.Indented)
    
65.                 '// ตัวอย่าง:
    
66.                 '// {
    
67.                 '//  "to": "USER_ID",
    
68.                 '//  "messages": [
    
69.                 '//     {
    
70.                 '//       "type": "text",
    
71.                 '//       "text": "สวัสดีครับ! นี่คือข้อความจาก Line Messaging API"
    
72.                 '//     },
    
73.                 '//     {
    
74.                 '//       "type": "image",
    
75.                 '//       "originalContentUrl": "https://example.com/image.jpg",
    
76.                 '//       "previewImageUrl": "https://example.com/image_preview.jpg" (หรือใช้ชื่อไฟล์ภาพ Content ตัวเดียวกันได้เลย)
    
77.                 '//     }
    
78.                 '//   ]
    
79.                 '// }
    
80.                 Dim content = New StringContent(JsonPayload, Encoding.UTF8, "application/json")
    
81.                 Dim response = Await client.PostAsync(url, content)
    
82.                 Dim responseBody = Await response.Content.ReadAsStringAsync()
    
83.                 '//
    
84.                 If Not response.IsSuccessStatusCode Then
    
85.                     MessageBox.Show("เกิดข้อผิดพลาด: " & response.StatusCode & vbCrLf & responseBody, "Report Error", MessageBoxButtons.OK, MessageBoxIcon.Error)
    
86.                 End If
    
87.                 '// หากต้องการแสดงข้อความแจ้งเตือน
    
88.                 'If response.IsSuccessStatusCode Then
    
89.                 'MessageBox.Show("ส่งข้อความและรูปภาพสำเร็จ!", "Complete", MessageBoxButtons.OK, MessageBoxIcon.Information)
    
90.                 'Else
    
91.                 'MessageBox.Show("เกิดข้อผิดพลาด: " & response.StatusCode & vbCrLf & responseBody, "Report Error", MessageBoxButtons.OK, MessageBoxIcon.Error)
    
92.                 'End If
    
93.             End Using
    
94.         Catch ex As Exception
    
95.             MessageBox.Show("LINE Exception: " & ex.Message)
    
96.         End Try
    
97.     End Function
    
98. End Class

คัดลอกไปที่คลิปบอร์ด

ดาวน์โหลดโค้ดต้นฉบับ VB.NET (.Net Framework 4.5+) ได้ที่นี่ ...