[VB.NET] การหาชุดของความยาวด้านของสามเหลี่ยมมุมฉาก (Pythagoras) ด้วย Parallel Programming

thongkorn

โค้ดชุดนี้นำเสนอการใช้ Parallel Programming ใน .NET เพื่อประมวลผลลูปซ้อน (Nested Loop) โดยสามารถใช้ Parallel.For และ Parallel.ForEach ซึ่งเป็นส่วนหนึ่งของ System.Threading.Tasks เพื่อกระจายการประมวลผลไปยังหลายๆคอร์ของ CPU ได้ ... โค้ดชุดนี้จะแสดงตัวอย่างวิธีการทำ Parallel Programming ในการหาค่าสามเหลี่ยมพีทาโกรัสด้วยการใช้ Parallel.For ในการประมวลผลลูปซ้อน ช่วยเพิ่มประสิทธิภาพในการหาสามเหลี่ยมพีทาโกรัสและเป็นวิธีที่ดีในการใช้ประโยชน์จากการทำงานแบบขนานใน .NET


ประโยชน์ของ Parallel Programming:
- เพิ่มประสิทธิภาพการทำงาน: การทำงานแบบขนานทำให้สามารถประมวลผลได้เร็วขึ้นโดยใช้หลายๆคอร์ของ CPU
- การใช้ทรัพยากร CPU อย่างมีประสิทธิภาพ: ช่วยลดการใช้ทรัพยากร CPU ของ Thread เดียวที่อาจทำให้การทำงานของระบบช้าลง


นอกจากนี้แอดมินได้เพิ่มเติมเรื่อง Lambda Expression เข้ามาช่วยในเรื่องของการเปรียบเทียบค่า เพื่อทำการจัดลำดับข้อมูลให้เรียงจากน้อยไปหามากด้วย ...


ข้อมูลเพิ่มเติม ...
'// Parallel programming in .NET: A guide to the documentation.

'// Data Parallelism (Task Parallel Library)

'// How to: Write a Simple Parallel.For Loop


มาดูโค้ดฉบับเต็มกันเถอะ ...

1. Imports System.Threading
   
2. Imports System.Threading.Tasks
   
3. 
   
4. Public Class frmPythagorasParallel
   
5.     '/ Start-Stop Timer
   
6.     Private mTimeDouble As Double
   
7.     Private sWatch As New Stopwatch()
   
8. 
   
9.     Private Sub frmThreadNestedLoop_Load(sender As System.Object, e As System.EventArgs) Handles MyBase.Load
   
10.         '// วนลูปผ่านคอนโทรลทั้งหมดบนฟอร์ม
    
11.         For Each ctrl As Control In Me.Controls
    
12.             '// ตรวจสอบว่าคอนโทรลเป็น Label หรือไม่
    
13.             If TypeOf ctrl Is Label Then
    
14.                 '// ตั้งค่าข้อความของ Label เป็นค่าว่าง
    
15.                 CType(ctrl, Label).Text = String.Empty
    
16.             End If
    
17.         Next
    
18.     End Sub
    
19. 
    
20.     ' / -------------------------------------------------------------------------------------------------
    
21.     ' / การใช้ LINQ ใน VB.NET เพื่อหาชุดของความยาวด้านของสามเหลี่ยมมุมฉาก
    
22.     ' / Pythagorean Triplets ที่เป็นเลขจำนวนเต็มทั้งหมดที่จะเป็นไปได้ดังนี้
    
23.     ' / -------------------------------------------------------------------------------------------------
    
24.     Private Sub btnLinq_Click(sender As System.Object, e As System.EventArgs) Handles btnLinq.Click
    
25.         Call InitializeListView(ListView1)
    
26.         '// สร้าง ListViewItem เพื่อเก็บข้อมูล
    
27.         Dim items As New List(Of ListViewItem)
    
28.         Dim MaxValue As Integer = 100
    
29.         sWatch.Reset()
    
30.         sWatch.Start()
    
31.         Cursor = Cursors.WaitCursor
    
32.         ' / -------------------------------------------------------------------------------------------------
    
33.         ' / LINQ ให้เริ่มนับ b = 1
    
34.         Dim PythagoreanTriple =
    
35.             From a In Enumerable.Range(1, MaxValue)
    
36.             From b In Enumerable.Range(1, MaxValue)
    
37.             Let c = Math.Sqrt(a * a + b * b)
    
38.             Where (c = Math.Floor(c) AndAlso c <= MaxValue)
    
39.             Select New With {a, b, c}
    
40.         ' / -------------------------------------------------------------------------------------------------
    
41.         For Each triplet In PythagoreanTriple
    
42.             '// สำหรับ ListView Control
    
43.             Dim NewItem As New ListViewItem(triplet.a) '// กำหนดค่าให้กับคอลัมน์แรก
    
44.             NewItem.SubItems.Add(triplet.b) ' เพิ่มค่าในคอลัมน์ที่สอง
    
45.             NewItem.SubItems.Add(triplet.c) ' เพิ่มค่าในคอลัมน์ที่สาม
    
46.             items.Add(NewItem)
    
47.         Next
    
48.         '// แสดงผลลัพธ์ใน ListView Control
    
49.         ListView1.Items.AddRange(items.ToArray())
    
50.         Cursor = Cursors.Default
    
51.         sWatch.Stop()
    
52.         mTimeDouble = sWatch.ElapsedMilliseconds * 0.001
    
53.         lblTimerLinq.Text = "เวลา LINQ : " & mTimeDouble.ToString & " sec."
    
54.         lblCountLinq.Text = "จำนวน : " & Format(ListView1.Items.Count, "#,##")
    
55.     End Sub
    
56. 
    
57.     ' / -------------------------------------------------------------------------------------------------
    
58.     ' / การใช้ Parallel.For ใน VB.NET เพื่อหาชุดของความยาวด้านของสามเหลี่ยมมุมฉาก
    
59.     ' / -------------------------------------------------------------------------------------------------
    
60.     Private Sub btnParallelOne_Click(sender As System.Object, e As System.EventArgs) Handles btnParallelOne.Click
    
61.         Call InitializeListView(ListView2)
    
62.         '// สร้าง ListViewItem เพื่อเก็บข้อมูล
    
63.         Dim items As New List(Of ListViewItem)
    
64.         Dim MaxValue As Integer = 101
    
65.         Dim Count As Integer = 0
    
66.         sWatch.Reset()
    
67.         sWatch.Start()
    
68.         Cursor = Cursors.WaitCursor
    
69.         '// Parallel Programming .NET
    
70.         '// สร้างตัวแปร results: เป็น List แบบ Tuple สำหรับเก็บผลลัพธ์ของชุดสามเหลี่ยมพีทาโกรัส
    
71.         Dim results As New List(Of Tuple(Of Integer, Integer, Integer))
    
72.         '// สร้างตัวแปร lock: ใช้สำหรับการป้องกันการเข้าถึงพร้อมกัน (Synchronization) ของหลายเธรด
    
73.         Dim lock As New Object()
    
74.         '// Parallel.For: ใช้เพื่อดำเนินการวนลูปแบบขนาน โดยในแต่ละรอบของลูปจะทำงานในเธรดต่างๆ
    
75.         Parallel.For(1, MaxValue, Sub(a)
    
76.                                       Parallel.For(1, MaxValue, Sub(b)
    
77.                                                                     Parallel.For(1, MaxValue, Sub(c)
    
78.                                                                                                   If a * a + b * b = c * c Then
    
79.                                                                                                       SyncLock lock '// ป้องกันการเข้าถึงพร้อมกัน
    
80.                                                                                                           '// สร้าง List ของทูเพิล (Tuple)
    
81.                                                                                                           results.Add(Tuple.Create(a, b, c))
    
82.                                                                                                           Count += 1
    
83.                                                                                                       End SyncLock
    
84.                                                                                                   End If
    
85.                                                                                               End Sub)
    
86.                                                                 End Sub)
    
87.                                   End Sub)
    
88.         Cursor = Cursors.Default
    
89.         sWatch.Stop()
    
90.         mTimeDouble = sWatch.ElapsedMilliseconds * 0.001
    
91.         lblTimerParallelOne.Text = "เวลา Pararllel I : " & mTimeDouble.ToString & " sec."
    
92.         '// ใช้ Lambda expression เพื่อสร้างฟังก์ชันเปรียบเทียบในตัว
    
93.         '// Function(x, y): นี่คือฟังก์ชันเปรียบเทียบที่กำหนดเองในรูปแบบของ Lambda expression
    
94.         '// ซึ่งใช้เพื่อเปรียบเทียบองค์ประกอบสองตัวในรายการที่กำลังจัดเรียง ฟังก์ชันนี้มีสองพารามิเตอร์ x และ y ซึ่งแทนทูเพิลสองตัวที่กำลังเปรียบเทียบ
    
95.         '// x.Item1.CompareTo(y.Item1): เมธอด CompareTo ใช้เพื่อเปรียบเทียบค่าในฟิลด์ Item1 ของทูเพิล x กับค่าในฟิลด์ Item1 ของทูเพิล y
    
96.         '// ถ้าค่า Item1 ของ x น้อยกว่าค่า Item1 ของ y เมธอด CompareTo จะคืนค่าเป็นค่าลบ
    
97.         '// ถ้าค่า Item1 ของ x เท่ากับค่า Item1 ของ y เมธอด CompareTo จะคืนค่าเป็น 0
    
98.         '// ถ้าค่า Item1 ของ x มากกว่าค่า Item1 ของ y เมธอด CompareTo จะคืนค่าเป็นค่าบวก
    
99.         '// โค้ดในการจัดเรียงข้อมูลตามคอลัมน์แรก
    
100.         results.Sort(Function(x, y) x.Item1.CompareTo(y.Item1))
     
101. 
     
102.         '// จัดเรียงข้อมูลตาม 2 หลักแรก
     
103.         'results.Sort(Function(x, y)
     
104.         'Dim comp1 = x.Item1.CompareTo(y.Item1)
     
105.         'If comp1 <> 0 Then Return comp1
     
106. 
     
107.         'Return x.Item2.CompareTo(y.Item2)
     
108.         '             End Function)
     
109. 
     
110.         '// จัดเรียงข้อมูลตาม 3 หลักแรก
     
111.         'results.Sort(Function(x, y)
     
112.         'Dim comp1 = x.Item1.CompareTo(y.Item1)
     
113.         'If comp1 <> 0 Then Return comp1
     
114. 
     
115.         'Dim comp2 = x.Item2.CompareTo(y.Item2)
     
116.         'If comp2 <> 0 Then Return comp2
     
117. 
     
118.         'Return x.Item3.CompareTo(y.Item3)
     
119.         '              End Function)
     
120. 
     
121.         For Each triplet In results
     
122.             '// สำหรับ ListView Control
     
123.             Dim NewItem As New ListViewItem(triplet.Item1) '// กำหนดค่าให้กับคอลัมน์แรก
     
124.             NewItem.SubItems.Add(triplet.Item2) ' เพิ่มค่าในคอลัมน์ที่สอง
     
125.             NewItem.SubItems.Add(triplet.Item3) ' เพิ่มค่าในคอลัมน์ที่สาม
     
126.             items.Add(NewItem)
     
127.         Next
     
128.         '// แสดงผลลัพธ์ใน ListView Control
     
129.         ListView2.Items.AddRange(items.ToArray())
     
130.         lblCountParallelOne.Text = "จำนวน : " & Format(Count, "#,##")
     
131.     End Sub
     
132. 
     
133.     ' / -------------------------------------------------------------------------------------------------
     
134.     ' / การใช้ Parallel.For ใน VB.NET เพื่อหาชุดของความยาวด้านของสามเหลี่ยมมุมฉาก
     
135.     ' / -------------------------------------------------------------------------------------------------
     
136.     Private Sub btnParallelTwo_Click(sender As System.Object, e As System.EventArgs) Handles btnParallelTwo.Click
     
137.         Call InitializeListView(ListView3)
     
138.         '// สร้าง ListViewItem เพื่อเก็บข้อมูล
     
139.         Dim items As New List(Of ListViewItem)
     
140.         Dim MaxValue As Integer = 100
     
141.         Dim Count As Integer = 0
     
142.         sWatch.Reset()
     
143.         sWatch.Start()
     
144.         Cursor = Cursors.WaitCursor
     
145. 
     
146.         '// Parallel Programming .NET
     
147.         '// สร้างตัวแปร results: เป็น List แบบ Tuple สำหรับเก็บผลลัพธ์ของชุดสามเหลี่ยมพีทาโกรัส
     
148.         Dim results As New List(Of Tuple(Of Integer, Integer, Integer))
     
149.         '// สร้างตัวแปร lock: ใช้สำหรับการป้องกันการเข้าถึงพร้อมกัน (Synchronization) ของหลายเธรด
     
150.         Dim lock As New Object()
     
151.         '// Parallel.For: ใช้เพื่อดำเนินการวนลูปแบบขนาน โดยในแต่ละรอบของลูปจะทำงานในเธรดต่างๆ
     
152.         Parallel.For(1, MaxValue, Sub(a)
     
153.                                       For b As Integer = 1 To MaxValue
     
154.                                           For c As Integer = 1 To MaxValue
     
155.                                               If a * a + b * b = c * c Then
     
156.                                                   SyncLock lock
     
157.                                                       results.Add(Tuple.Create(a, b, c))
     
158.                                                       Count += 1 '// นับจำนวนคำตอบ
     
159.                                                   End SyncLock
     
160.                                               End If
     
161.                                           Next
     
162.                                       Next
     
163.                                   End Sub)
     
164. 
     
165.         Cursor = Cursors.Default
     
166.         sWatch.Stop()
     
167.         mTimeDouble = sWatch.ElapsedMilliseconds * 0.001
     
168.         lblTimerParallelTwo.Text = "เวลา Pararllel II : " & mTimeDouble.ToString & " sec."
     
169.         '// จัดเรียงข้อมูลตามคอลัมน์แรก
     
170.         'results.Sort(Function(x, y) x.Item1.CompareTo(y.Item1))
     
171.         '// จัดเรียงข้อมูลตาม 2 หลักแรก
     
172.         'results.Sort(Function(x, y)
     
173.         'Dim comp1 = x.Item1.CompareTo(y.Item1)
     
174.         'If comp1 <> 0 Then Return comp1
     
175. 
     
176.         'Return x.Item2.CompareTo(y.Item2)
     
177.         '             End Function)
     
178. 
     
179.         '// จัดเรียงข้อมูลตาม 3 หลักแรก
     
180.         results.Sort(Function(x, y)
     
181.                          Dim comp1 = x.Item1.CompareTo(y.Item1)
     
182.                          If comp1 <> 0 Then Return comp1
     
183. 
     
184.                          Dim comp2 = x.Item2.CompareTo(y.Item2)
     
185.                          If comp2 <> 0 Then Return comp2
     
186. 
     
187.                          Return x.Item3.CompareTo(y.Item3)
     
188.                      End Function)
     
189.         '// แสดงผลลัพธ์
     
190.         For Each triplet In results
     
191.             '// สำหรับ ListView Control
     
192.             Dim NewItem As New ListViewItem(triplet.Item1) '// กำหนดค่าให้กับคอลัมน์แรก
     
193.             NewItem.SubItems.Add(triplet.Item2) ' เพิ่มค่าในคอลัมน์ที่สอง
     
194.             NewItem.SubItems.Add(triplet.Item3) ' เพิ่มค่าในคอลัมน์ที่สาม
     
195.             items.Add(NewItem)
     
196.         Next
     
197.         '// แสดงผลลัพธ์ใน ListView Control
     
198.         ListView3.Items.AddRange(items.ToArray())
     
199.         lblCountParallelTwo.Text = "จำนวน : " & Format(Count, "#,##")
     
200.     End Sub
     
201. 
     
202.     ' / -------------------------------------------------------------------------------------------------
     
203.     ' / Initialized ListView Control.
     
204.     ' / -------------------------------------------------------------------------------------------------
     
205.     Private Sub InitializeListView(LV As ListView)
     
206.         With LV
     
207.             .Columns.Clear() '// make sure columns collection is empty.
     
208.             .Items.Clear()
     
209.             .View = View.Details
     
210.             .GridLines = True
     
211.             .FullRowSelect = True
     
212.             .HideSelection = False
     
213.             .MultiSelect = True 'False
     
214.             '// Add 3 columns
     
215.             .Columns.Add("A")
     
216.             .Columns.Add("B")
     
217.             .Columns.Add("C")
     
218.         End With
     
219.         With LV
     
220.             .Columns(0).Width = ListView1.Width \ 3 - 10
     
221.             .Columns(1).Width = ListView1.Width \ 3 - 10
     
222.             .Columns(2).Width = ListView1.Width \ 3 - 5
     
223.         End With
     
224.     End Sub
     
225. 
     
226.     Private Sub frmPythagorasParallel_FormClosed(sender As Object, e As System.Windows.Forms.FormClosedEventArgs) Handles Me.FormClosed
     
227.         Me.Dispose()
     
228.         GC.SuppressFinalize(Me)
     
229.         Application.Exit()
     
230.     End Sub
     
231. 
     
232. End Class

คัดลอกไปที่คลิปบอร์ด

ดาวน์โหลดโค้ดต้นฉบับเต็ม VB.NET (2010) ได้ที่นี่ ...