[VB6] การอ่านค่า Serial Number ของ USB Flash Drive ด้วย WMI

thongkorn

สำหรับกระบวนการขั้นตอนวิธีคิด แอดมินได้อธิบายไปแล้วในส่วนของโค้ด VB.Net ซึ่งก็ใช้หลักการเดียวกันนั่นแหละครับ (คลิ๊กที่นี่เพื่อไปดูโค้ด VB.Net) สำหรับโค้ด VB6 แอดมินได้แก้ไขเพิ่มเติม โดยแนะนำการใช้งานคำสั่งพื้นฐานบางอย่าง ซึ่งเราจำเป็นต้องใช้กันบ่อยมาก คือ คำสั่งภายใน (ฟังค์ชั่น) In String หรือ InStr และ InStrRev โดยที่
InStr คือ การค้นหาข้อความที่ต้องการจากทางซ้ายไปทางขวา หากเจอตัวแรกก็จะคืน ค่าตำแหน่งที่มันอยู่ กลับไป หากไม่เจอก็คืนค่ากลับ 0 (นั่นคือฟังค์ชั่นที่มีการคืนค่าเลขจำนวนเต็ม)

InstrRev ก็จะทำกลับด้านกัน คือไล่จากทางขวามาทางซ้ายแทน

เช่น ...
i = InStr("ABCD", "B") ... ค่า i = 2 เพราะ B อยู่ตำแหน่งที่ 2 จากทางซ้ายมือ
i = InStrRev("ABCD", "C") ... ค่า i = 3 เพราะ C อยู่ตำแหน่งที่ 3 จากทางซ้ายมือ (เอาตำแหน่งที่เจอ)
i = InStrRev("ABCDC", "C") ... ค่า i = 5 เพราะเจอ C ตัวแรก จากทางขวามาซ้าย ซึ่งอยู่ตำแหน่งที่ 5


มาดูโค้ดฉบับเต็ม ...

1. ' / --------------------------------------------------------------------------------
   
2. ' / Developer : Mr.Surapon Yodsanga (Thongkorn Tubtimkrob)
   
3. ' / eMail : thongkorn@hotmail.com
   
4. ' / URL: http://www.g2gnet.com (Khon Kaen - Thailand)
   
5. ' / Facebook: http://www.facebook.com/g2gnet (For Thailand only)
   
6. ' / Facebook: http://www.facebook.com/CommonIndy (Worldwide)
   
7. ' / UsbFlashSerialNoWMI:  Read Serial Number of USB Flash Drive with WMI
   
8. ' / WMI = Windows Management Instrumentation
   
9. ' / Microsoft Visual Basic 6.0 Service Pack 6
   
10. ' /
    
11. ' / This is open source code under @CopyLeft by Thongkorn Tubtimkrob.
    
12. ' / You can modify and/or distribute without to inform the developer.
    
13. ' / --------------------------------------------------------------------------------
    
14. Option Explicit
    
15. 
    
16. Private Sub Form_Load()
    
17.     Me.Move (Screen.Width - Width) \ 2, (Screen.Height - Height) \ 2
    
18.     txtUsbFlash.Text = ""
    
19.     txtUsbFlash.SelText = "USB FLASH SERIAL NUMBER" & vbCrLf & GetSerialWMI
    
20. End Sub
    
21. 
    
22. Public Function GetSerialWMI() As String
    
23.     Dim strComputer As String
    
24.     Dim objWMIService As Object
    
25.     Dim ColItems As Object
    
26.     Dim ObjItem As Object
    
27.     Dim strSerial As String
    
28.     Dim strTemp As String
    
29.     Dim strArr() As String
    
30.     Dim MaxLen As Byte '<-- หาค่าความยาวสูงสุดของชุดข้อมูล ซึ่งจะเป็น Serial Number
    
31.     Dim idx As Byte '<-- เป็น Index ของ Array ซึ่งจะเก็บค่าคำตอบ Serial Number
    
32.    
    
33.     '/ (dot) is Local machine
    
34.     strComputer = "."
    
35.     Set objWMIService = GetObject("winmgmts:\" & strComputer & "\root\CIMV2")
    
36.     '/ DiskDrive Class
    
37.     Set ColItems = objWMIService.ExecQuery("SELECT * FROM Win32_DiskDrive", , 48)
    
38.     '/ Detect USB Flash All Drive
    
39.     For Each ObjItem In ColItems
    
40.         If ObjItem.interfacetype = "USB" Then
    
41.             '// เช่น "USBSTOR\DISK&VEN_&PROD_&REV_1.00\7&15FF80F3&0&__&0"
    
42.             strTemp = ObjItem.pnpdeviceid
    
43.             '// InStrRev ค้นหาเครื่องหมาย \ จากทางขวามาซ้าย หากพบให้ +1 เพื่อเริ่มต้นการอ่านค่าจากฟังค์ชั่น Mid String
    
44.             strTemp = Mid(strTemp, InStrRev(strTemp, "") + 1)
    
45.             '// ผลที่ได้ "7&15FF80F3&0&__&0"
    
46.             '// จึงต้องแยกเครื่องหมาย & ออกจากชุดข้อมูล
    
47.             strArr = Split(strTemp, "&")
    
48.             '// ผลที่ได้
    
49.             ' strArr(0) = "7"               '<-- LBound
    
50.             ' strArr(1) = "15FF80F3"
    
51.             ' strArr(2) = "0"
    
52.             ' strArr(3) = "__"
    
53.             ' strArr(4) = "0"               '<-- UBound
    
54.             '/ หาความยาวสูงสุดของชุดข้อมูลจาก Array
    
55.             '/ ลูปตามจำนวน Index ของ Array โดยเริ่มจาก LBound = 0 ไปจนสิ้นสุดที่ UBound
    
56.             Dim Count As Byte
    
57.             MaxLen = 0: idx = 0 '<-- เคลียร์ค่าเดิม กรณีหากมี USB Flash Drive หลายตัว มิเช่นนั้นจะเกิด Bug (Logical Error)
    
58.             For Count = LBound(strArr) To UBound(strArr)
    
59.                 '// เปรียบเทียบค่าความยาวของข้อมูลในแต่ละ Array
    
60.                 If MaxLen < Len(strArr(Count)) Then
    
61.                     '// เก็บค่า Index ไว้เป็นคำตอบ (ตัวอย่างคือ Index = 1)
    
62.                     idx = Count
    
63.                     '// นำค่าความยาวที่มากกว่ามาเก็บไว้ ก่อนที่วนกลับไปเปรียบเทียบค่าใหม่
    
64.                     MaxLen = Len(strArr(Count))
    
65.                 End If
    
66.             Next
    
67.             '// เก็บค่าคำตอบ
    
68.             strSerial = strSerial & strArr(idx) & vbCrLf
    
69.         End If
    
70.     Next
    
71.     '/ Return value
    
72.     GetSerialWMI = strSerial
    
73. End Function
    
74. 
    
75. Private Sub Form_Resize()
    
76.     If WindowState <> vbMinimized Then
    
77.         txtUsbFlash.Move 0, 0, ScaleWidth, ScaleHeight
    
78.     End If
    
79. End Sub

คัดลอกไปที่คลิปบอร์ด

ดาวน์โหลดโค้ดฉบับเต็ม VB6 (SP6) ได้ที่นี่ ...

MrDen

ขอบคุณมากครับผม  ขอให้สุขภาพแข็งแรง เงินทองไหลมาเทมา ครับผม.

mozza

wowww สุดยอดคับ